Add basic functionality

Author: stephan-gh

src/main/groovy/net/minecrell/gitpatcher/GitPatcher.groovy

@@ -21,20 +21,53 @@
  */
 package net.minecrell.gitpatcher
 
+import net.minecrell.gitpatcher.task.UpdateSubmodulesTask
+import net.minecrell.gitpatcher.task.patch.ApplyPatchesTask
+import net.minecrell.gitpatcher.task.patch.MakePatchesTask
 import org.gradle.api.Plugin
 import org.gradle.api.Project
 
 class GitPatcher implements Plugin<Project> {
 
-    private Project project
+    protected Project project
+    protected PatchExtension extension
 
     @Override
     void apply(Project project) {
         this.project = project
+        project.with {
+            this.extension = extensions.create('patches', PatchExtension)
+            extension.root = projectDir
+
+            task('updateSubmodules', type: UpdateSubmodulesTask)
+            task('applyPatches', type: ApplyPatchesTask) {
+                dependsOn 'updateSubmodules'
+            }
+            task('makePatches', type: MakePatchesTask)
+
+            afterEvaluate {
+                // Configure the settings from our extension
+                configure([tasks.applyPatches, tasks.makePatches]) {
+                    repo = extension.target
+                    root = extension.root
+                    submodule = extension.submodule
+                    patchDir = extension.patches
+                }
+
+                tasks.updateSubmodules.with {
+                    repo = extension.root
+                    submodule = extension.submodule
+                }
+            }
+        }
     }
 
     Project getProject() {
-        project
+        return project
+    }
+
+    PatchExtension getExtension() {
+        return extension
     }
 
 }

src/main/groovy/net/minecrell/gitpatcher/PatchExtension.groovy

@@ -0,0 +1,13 @@
+package net.minecrell.gitpatcher
+
+class PatchExtension {
+
+    File root
+
+    String submodule
+
+    File target
+
+    File patches
+
+}

src/main/groovy/net/minecrell/gitpatcher/git/MailPatch.groovy

@@ -0,0 +1,152 @@
+package net.minecrell.gitpatcher.git
+
+import groovy.transform.EqualsAndHashCode
+import groovy.transform.ToString
+import org.apache.commons.lang.StringUtils
+import org.eclipse.jgit.api.Git
+import org.eclipse.jgit.diff.DiffFormatter
+import org.eclipse.jgit.lib.PersonIdent
+import org.eclipse.jgit.lib.Repository
+import org.eclipse.jgit.revwalk.RevCommit
+import org.joda.time.DateTime
+import org.joda.time.DateTimeZone
+import org.joda.time.format.DateTimeFormat
+import org.joda.time.format.DateTimeFormatter
+
+@EqualsAndHashCode
+@ToString(includePackage = false)
+class MailPatch {
+
+    private static final JGIT_VERSION = 'jgit/' + (Git.class.getPackage().getImplementationVersion() ?: 'unknown')
+
+    private static final DateTimeFormatter dateFormat =
+            DateTimeFormat.forPattern("EEE, d MMM yyyy HH:mm:ss Z").withLocale(Locale.US).withOffsetParsed()
+
+    final PersonIdent author
+    final String message
+
+    MailPatch(PersonIdent author, String message) {
+        this.author = author
+        this.message = message
+    }
+
+    boolean represents(RevCommit commit) {
+        return author == commit.authorIdent && message == commit.fullMessage
+    }
+
+    static MailPatch parse(InputStream is) {
+        return parse(is.newReader('UTF-8'))
+    }
+
+    static MailPatch parse(BufferedReader reader) {
+        String from = null
+        String time = null
+        StringBuilder builder = null
+
+        String line
+        while ((line = reader.readLine()) != null) {
+            if (line.isEmpty()) {
+                continue
+            }
+
+            if (line.startsWith('diff')) {
+                break
+            }
+
+            if (builder == null) {
+                int pos = line.indexOf(':')
+                if (pos == -1) {
+                    continue
+                }
+
+                def header = line.substring(0, pos)
+                def content = line.substring(pos + 2)
+                switch (header) {
+                    case "From":
+                        from = content
+                        break
+                    case "Date":
+                        time = content
+                        break
+                    case "Subject":
+                        builder = new StringBuilder(StringUtils.removeStart(content, '[PATCH] '))
+                }
+            } else {
+                builder << line.trim()
+            }
+        }
+
+        assert from != null, 'Missing commit author'
+        assert time != null, 'Missing commit date'
+        assert builder != null, 'Missing commit message'
+
+        def author = parseAuthor(from)
+        def date = dateFormat.parseDateTime(time)
+        def message = builder.toString()
+
+        return new MailPatch(new PersonIdent(author[0], author[1], date.toDate(), date.getZone().toTimeZone()), message)
+    }
+
+    private static String[] parseAuthor(String author) {
+        int start = author.lastIndexOf('<')
+        assert start != -1, 'Incomplete commit author'
+
+        def name = unquote(author.substring(0, start - 1))
+
+        def end = author.lastIndexOf('>')
+        assert start != -1, 'Invalid commit author'
+
+
+        return [name, author.substring(start + 1, end)]
+    }
+
+    private static String unquote(String s) {
+        if (s.length() > 2) {
+            if (s.charAt(0) == '"' as char && s.charAt(s.length() - 1) == '"' as char) {
+                return s.substring(1, s.length() - 1)
+            }
+        }
+
+        return s
+    }
+
+    static void writeHeader(RevCommit commit, Writer writer) {
+        writer << 'From ' << commit.id.name << ' Mon Sep 17 00:00:00 2001\n'
+        writer << 'From: ' << commit.authorIdent.name << ' <' << commit.authorIdent.emailAddress << '>\n'
+
+        writer << 'Date: '
+        dateFormat.printTo writer, new DateTime(commit.authorIdent.getWhen(), DateTimeZone.forTimeZone(commit.authorIdent.timeZone))
+        writer << '\n'
+
+        writer << 'Subject: [PATCH] ' << commit.fullMessage << '\n\n\n'
+        writer.flush()
+    }
+
+    static void writePatch(Repository repo, RevCommit commit, OutputStream out) {
+        def writer = out.newWriter('UTF-8')
+        writeHeader(commit, writer)
+
+        def formatter = new DiffFormatter(out)
+        formatter.repository = repo
+        formatter.format(commit.getParent(0).tree, commit.tree)
+
+        writer << '-- \n' << JGIT_VERSION << '\n'
+        writer.flush()
+    }
+
+
+    static String suggestFileName(RevCommit commit, int num) {
+        def result = new StringBuilder(String.format("%04d-", num))
+        for (char c : commit.shortMessage.chars) {
+            if (Character.isLetter(c) || Character.isDigit(c)) {
+                result << c
+            } else if (Character.isWhitespace(c) || c == '/' as char) {
+                result << '-' as char
+            }
+        }
+
+        result << '.patch'
+        return result.toString()
+    }
+
+}

src/main/groovy/net/minecrell/gitpatcher/git/Patcher.groovy

@@ -0,0 +1,39 @@
+package net.minecrell.gitpatcher.git
+
+import static org.eclipse.jgit.revwalk.RevSort.REVERSE
+import static org.eclipse.jgit.revwalk.RevSort.TOPO
+
+import groovy.transform.stc.ClosureParams
+import groovy.transform.stc.FirstParam
+import groovy.transform.stc.SimpleType
+import org.eclipse.jgit.api.Git
+import org.eclipse.jgit.revwalk.RevWalk
+
+final class Patcher {
+
+    private Patcher() {
+    }
+
+    static Git openGit(File repo, @ClosureParams(value = SimpleType, options = "org.eclipse.jgit.api.Git") @DelegatesTo(Git) Closure action) {
+        withGit(Git.open(repo), action)
+    }
+
+    static Git withGit(Git git, @ClosureParams(FirstParam) @DelegatesTo(Git) Closure action) {
+        action.delegate = git
+
+        try {
+            action.call(git)
+            return git
+        } finally {
+            git.close()
+        }
+    }
+
+    static RevWalk log(Git git, String start) {
+        RevWalk walk = git.log().not(git.repository.resolve(start)).call()
+        walk.sort(TOPO)
+        walk.sort(REVERSE, true)
+        return walk
+    }
+
+}

src/main/groovy/net/minecrell/gitpatcher/task/GitTask.groovy

@@ -0,0 +1,31 @@
+/*
+ * PoreGradle
+ * Copyright (c) 2015, Lapis <https://github.com/LapisBlue>
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+ * THE SOFTWARE.
+ */
+package net.minecrell.gitpatcher.task
+
+import org.gradle.api.DefaultTask
+
+abstract class GitTask extends DefaultTask {
+
+    File repo
+
+}

src/main/groovy/net/minecrell/gitpatcher/task/SubmoduleTask.groovy

@@ -0,0 +1,33 @@
+/*
+ * PoreGradle
+ * Copyright (c) 2015, Lapis <https://github.com/LapisBlue>
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+ * THE SOFTWARE.
+ */
+package net.minecrell.gitpatcher.task
+
+abstract class SubmoduleTask extends GitTask {
+
+    String submodule
+
+    {
+        onlyIf { submodule != null }
+    }
+
+}

src/main/groovy/net/minecrell/gitpatcher/task/UpdateSubmodulesTask.groovy

@@ -0,0 +1,52 @@
+/*
+ * PoreGradle
+ * Copyright (c) 2015, Lapis <https://github.com/LapisBlue>
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+ * THE SOFTWARE.
+ */
+package net.minecrell.gitpatcher.task
+
+import static net.minecrell.gitpatcher.git.Patcher.openGit
+
+import org.eclipse.jgit.submodule.SubmoduleStatus
+import org.eclipse.jgit.submodule.SubmoduleStatusType
+import org.gradle.api.tasks.TaskAction
+
+class UpdateSubmodulesTask extends SubmoduleTask {
+
+    @TaskAction
+    void updateSubmodules() {
+        openGit(repo) {
+            SubmoduleStatus status = submoduleStatus().addPath(submodule).call().get(submodule);
+            if (status.type == SubmoduleStatusType.INITIALIZED) {
+                didWork = false
+                return
+            }
+
+            if (status.type == SubmoduleStatusType.MISSING) {
+                submoduleInit().addPath(submodule).call()
+            } else if (status.type == SubmoduleStatusType.REV_CHECKED_OUT) {
+                logger.warn "Resetting submodule \"{}\" from {} back to {}", submodule, status.headId, status.indexId
+            }
+
+            submoduleUpdate().addPath(submodule).call()
+        }
+    }
+
+}