split-tests-java/build.gradle.kts at main · Donnerbart/split-tests-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
plugins {
    application
    java
    alias(libs.plugins.gradle.git.properties)
    alias(libs.plugins.shadow)
}

group = "de.donnerbart"
version = "0.1.32"

application {
    mainClass = "de.donnerbart.split.TestSplitMain"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

repositories {
    mavenCentral()
}

// ********** dependencies **********

dependencies {
    compileOnly(libs.jetbrains.annotations)
    implementation(libs.jackson.dataformat.xml)
    implementation(libs.java.parser)
    implementation(libs.jcommander)
    implementation(libs.logback.classic)
}

// ********** distribution **********

tasks.shadowJar {
    dependsOn(tasks.generateGitProperties)
    mergeServiceFiles()
    archiveBaseName = "split-tests-java"
    archiveClassifier = ""
    archiveVersion = ""
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    manifest {
        attributes["Main-Class"] = "de.donnerbart.split.TestSplitMain"
    }
}

// ********** tests **********

dependencies {
    testCompileOnly(libs.jetbrains.annotations)

    testImplementation(libs.junit.jupiter)
    testRuntimeOnly(libs.junit.platform.launcher)

    testImplementation(libs.assertj)
    testImplementation(libs.equalsVerifier)
}

tasks.test {
    dependsOn(tasks.generateGitProperties)
    useJUnitPlatform()
}

// ********** git properties **********

gitProperties {
    dotGitDirectory = project.rootProject.layout.projectDirectory.dir(".git")
    gitPropertiesName = "split-tests-java.properties"
    keys = listOf("git.branch", "git.commit.id", "git.commit.id.abbrev", "git.commit.time")
    customProperty("version", version)
    extProperty = "gitProps"
}
tasks.generateGitProperties {
    outputs.upToDateWhen { false }
}