Add a few more Process examples.

Author: jericks

examples/process_barnes_surface.groovy

@@ -0,0 +1,53 @@
+import geoscript.geom.*
+import geoscript.workspace.*
+import geoscript.layer.*
+import geoscript.feature.*
+import geoscript.style.*
+import geoscript.filter.Function
+import geoscript.process.*
+import geoscript.render.Map
+
+Bounds bounds = new Bounds(0,0,10,10,"EPSG:4326")
+
+Workspace workspace = new Memory()
+Layer layer = workspace.create(new Schema("grid",[
+    new Field("geom","Point","EPSG:4326"),
+    new Field("row","int"),
+    new Field("col","int"),
+    new Field("value","double")
+]))
+
+bounds.generateGrid(10,10,"point", {g,c,r ->
+    double value = 0
+    if (c in [1,2] && r in [1,2]) value = 1
+    if (c in [3,4] && r in [1,2,3,4] || c in [1,2] && r in [3,4]) value = 30
+    if (c in [5,6] && r in [1,2,3,4,5,6] || c in [1,2,3,4] && r in [5,6]) value = 60
+    if (c in [7,8] && r in [1,2,3,4,5,6,7,8] || c in [1,2,3,4,5,6] && r in [7,8]) value = 70
+    if (c in [9,10] && r in [1,2,3,4,5,6,7,8,9,10] || c in [1,2,3,4,5,6,7,8] && r in [9,10]) value = 100
+    layer.add([geom: g,col:c, row:r, value: value])
+})
+
+layer.style = new Shape("navy", 6, "circle", 0.55, 0) + new Label(new Function("Concatenate(value)")).point([0.5,0.5],[0,5])
+
+Process process = new Process("vec:BarnesSurface")
+results = process.execute([
+    data: layer.cursor,
+    valueAttr: "value",
+    scale: 300,
+    convergence: 0.3,
+    passes: 2,
+    minObservations: 1,
+    maxObservationDistance: 0,
+    pixelsPerCell: 1,
+    noDataValue: -999,
+    outputWidth: 100,
+    outputHeight: 100,
+    outputBBOX: layer.bounds
+])
+Raster raster = results.result
+raster.style = new ColorMap(raster, ["#f7da22","#ecbe1d","#e77124","#d54927","#cf3a27", "#a33936", "#7f182a", "#68101a"])
+
+Map map = new Map([layers:[raster, layer]])
+map.bounds = layer.bounds.expandBy(3)
+map.renderToImage()
+

examples/process_heatmap.groovy

@@ -0,0 +1,44 @@
+import geoscript.layer.*
+import geoscript.workspace.*
+import geoscript.layer.io.GeoJSONReader
+import geoscript.process.Process
+import geoscript.render.*
+import geoscript.style.*
+
+// Get earthquakes from USGS GeoJSON feed
+tempLayer = new GeoJSONReader().read(new URL("http://earthquake.usgs.gov/earthquakes/feed/v1.0/summary/all_week.geojson").text)
+Memory workspace = new Memory()
+layer = workspace.create(tempLayer.schema.reproject("EPSG:4326", "earthquakes"))
+tempLayer.eachFeature{f->
+    layer.add(f)
+}
+
+// Get the heatmap process
+process = new Process("vec:Heatmap")
+println "Process ${process.name} parameters: ${process.parameters}"
+
+// Create a heatmap of the earthquakes
+results = process.execute([
+        data: layer,
+        radiusPixels: 10,
+        pixelsPerCell: 10,
+        outputWidth: 600,
+        outputHeight: 400,
+        outputBBOX: layer.bounds
+])
+
+Raster raster = results.result
+println "Raster extrema: ${raster.extrema}"
+raster.style = new ColorMap([
+        [color: "#f7da22", quantity:0],
+        [color: "#ecbe1d", quantity:0.1],
+        [color: "#e77124", quantity:0.2],
+        [color: "#d54927", quantity:0.3],
+        [color: "#cf3a27", quantity:0.7],
+        [color: "#a33936", quantity:0.8],
+        [color: "#7f182a", quantity:0.9],
+        [color: "#68101a", quantity:1]
+])
+
+Map map = new Map([layers:[raster,layer]])
+map.renderToImage()

examples/process_point_stacker.groovy

@@ -0,0 +1,47 @@
+import geoscript.geom.*
+import geoscript.layer.*
+import geoscript.feature.*
+import geoscript.workspace.*
+import geoscript.layer.io.GeoJSONReader
+import geoscript.process.Process
+import geoscript.render.*
+import geoscript.style.*
+
+tempLayer = new GeoJSONReader().read(new URL("http://earthquake.usgs.gov/earthquakes/feed/v1.0/summary/all_week.geojson").text)
+Memory workspace = new Memory()
+layer = workspace.create(tempLayer.schema.reproject("EPSG:4326", "earthquakes"))
+tempLayer.eachFeature{f->
+    layer.add(f)
+}
+
+println "Layer ${layer.name} has ${layer.count} features!"
+println "   Schema: ${layer.schema}"
+println "   Bounds: ${layer.bounds}"
+println "   CRS: ${layer.proj?.id}"
+
+process = new Process("vec:PointStacker")
+println "Process ${process.name} parameters: ${process.parameters}"
+
+results = process.execute([
+        data: layer,
+        cellSize: 10,
+        outputWidth: 600,
+        outputHeight: 400,
+        outputBBOX: layer.bounds
+])
+
+Cursor cursor = results.result
+outLayer = workspace.create(new Schema("stacked",[["geom", "Point"],["count", "int"],["countunique", "int"]]))
+cursor.each{f ->
+    outLayer.add(f)
+}
+
+layer.style = new Shape(type: "triangle", size: 3, color: "red")
+outLayer.style = (
+(new Shape(type: "circle", size: 8, color: "wheat") + new Label("count").where("count >= 1 and count <=2")) +
+        (new Shape(type: "circle", size: 12, color: "wheat") + new Label("count").where("count > 2 and count <=4")) +
+        (new Shape(type: "circle", size: 18, color: "wheat") + new Label("count").where("count > 4"))
+)
+
+Map map = new Map(layers: [layer, outLayer])
+map.renderToImage()