Use vim's builtin format mapping

Author: tbodt

autoload/codefmt.vim

@@ -238,6 +238,16 @@ function! codefmt#FormatMap(type) range abort
   call codefmt#FormatLines(line("'["), line("']"))
 endfunction
 
+""
+" @public
+" To map the builtin |gq| command to invoke codefmt, set 'formatexpr' to call
+" this function. Example: >
+" set formatexpr=codefmt#FormatExpr()
+" <
+function! codefmt#FormatExpr() abort
+  call codefmt#FormatLines(v:lnum, v:lnum + v:count)
+endfunction
+
 ""
 " Generate the completion for supported formatters. Lists available formatters
 " that apply to the current buffer first, then unavailable formatters that
@@ -252,6 +262,23 @@ function! codefmt#GetSupportedFormatters(ArgLead, CmdLine, CursorPos) abort
   return join(l:groups[0] + l:groups[1] + l:groups[2], "\n")
 endfunction
 
+""
+" Returns whether there is a default formatter available for the current
+" buffer.
+function! codefmt#AvailableInCurrrentBuffer() abort
+  let l:formatters = s:registry.GetExtensions()
+  if !empty(get(b:, 'codefmt_formatter'))
+    let l:Predicate = {f -> f.name ==# b:codefmt_formatter}
+  else
+    let l:Predicate = {f -> f.AppliesToBuffer() && s:IsAvailable(f)}
+  endif
+  for l:formatter in s:registry.GetExtensions()
+    if l:Predicate(l:formatter)
+      return 1
+    endif
+  endfor
+  return 0
+endfunction
 
 ""
 " @private

plugin/mappings.vim

@@ -59,3 +59,14 @@ execute 'nnoremap <unique> <silent>' s:prefix . '=' ':FormatLines<CR>'
 " Format the visually selected region using the formatter associated with the
 " current buffer.
 execute 'vnoremap <unique> <silent>' s:prefix ':FormatLines<CR>'
+
+function! s:SetFormatExpr() abort
+  if codefmt#AvailableInCurrrentBuffer()
+    setlocal formatexpr=codefmt#FormatExpr()
+  endif
+endfunction
+
+augroup codefmt_formatexpr
+  autocmd!
+  autocmd BufEnter * call <SID>SetFormatExpr()
+augroup END