sparkles/apps/javalin/entity/build.gradle at 432487fb206882b53fbb4e394fc86c49f8a296dd · sparkles-dev/sparkles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
import org.apache.tools.ant.filters.*

plugins {
  id 'java'
  id 'application'
  id 'com.adarshr.test-logger'
  id 'com.palantir.git-version'
  id 'com.palantir.docker'
  id 'org.inferred.processors'
}

group = 'sparkles'
version = gitVersion()
description = 'An entity framework for Javalin'

mainClassName = 'sparkles.EntityApp'
sourceCompatibility = 1.8
targetCompatibility = 1.8

dependencies {
  // 3rd party
  implementation 'com.google.guava:guava:27.0.1-jre'
  implementation 'io.javalin:javalin:3.+'
  implementation 'io.jsonwebtoken:jjwt:0.9.1'
  implementation 'org.hibernate.javax.persistence:hibernate-jpa-2.1-api:1.0.2.Final'
  implementation 'org.hibernate:hibernate-core:5.4.10.Final'
  implementation 'org.hsqldb:hsqldb:2.5.0'
  implementation 'org.slf4j:slf4j-api:1.7.29'
  implementation 'org.slf4j:slf4j-simple:1.7.29'
  implementation 'org.springframework.data:spring-data-commons:2.2.3.RELEASE'
  implementation 'org.springframework.data:spring-data-jpa:2.2.3.RELEASE'

  // project
  implementation project(':support:common:util')
  implementation project(':support:common:flyway')
  implementation project(':support:javalin:api')
  implementation project(':support:javalin:persistence:flyway')
  implementation project(':support:javalin:security:jwt')
  implementation project(':support:javalin:security:keycloak')
  implementation project(':support:javalin:persistence:springdata')

  // apt
  processor 'org.projectlombok:lombok:1.18.42'

  // testing
  testImplementation project(':support:javalin:testing')
  testImplementation 'com.squareup.okhttp3:okhttp:3.+'
  testImplementation 'io.javalin:javalin:3.+'
  testImplementation 'junit:junit:4.+'
  testImplementation 'org.assertj:assertj-core:3.14.0'
}

processResources {

  with copySpec {
    from 'src/main/filteredResources'
    filter(ReplaceTokens, tokens: [
      buildApp: 'momed',
      buildVersion: gitVersion(),
      buildTime: new Date().format('yyyy-MM-dd\'T\'HH:mm:ss\'Z\''),
      gradleVersion: gradle.gradleVersion
    ])
  }
}

docker {
  name 'sparkles/entity'
  dockerfile file("${rootDir}/tools/docker/gradle-app/Dockerfile")
  files tasks.distZip.outputs
  buildArgs([bin: 'entity', zip: tasks.distZip.archiveName])
  pull true
}

run.doFirst {
  environment 'ENVIRONMENT', 'develop'
}

testlogger {
  theme 'mocha'
  showStandardStreams true
}