agent-box/flake.nix at main · 0xferrous/agent-box · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
{
  description = "Agent Box - Git repository management tool";

  nixConfig = {
    extra-substituters = [ "https://0xferrous.cachix.org" ];
    extra-trusted-public-keys = [
      "0xferrous.cachix.org-1:p38oLu+8I+EwBW6NCl+ffI8qn+WOtUeRzES/dYNuSUE="
    ];
  };

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = { self, nixpkgs, flake-utils, rust-overlay }:
    (flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ (import rust-overlay) ];
        };
        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
          extensions = [ "rustfmt" "clippy" ];
        };

        workspaceToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
        wrappersCrateToml = builtins.fromTOML (builtins.readFile ./wrappers/Cargo.toml);
        portalCrateToml = builtins.fromTOML (builtins.readFile ./portal/Cargo.toml);
        abCrateToml = builtins.fromTOML (builtins.readFile ./ab/Cargo.toml);

        portalHostBin = "${portalCrateToml.package.name}-host";

        mdbook-excalidraw = pkgs.rustPlatform.buildRustPackage {
          pname = "mdbook-excalidraw";
          version = "0.1.0";
          src = pkgs.fetchFromGitHub {
            # inherit pname version;
            owner = "peachycloudsecurity";
            repo = "mdbook-excalidraw";
            rev = "2d8f07905f57d1c460ccb9f7279af4f4999b9ee2";
            sha256 = "sha256-Sf2cWaoZ3tOjRWaOp898RME6+7uLYv9gb7RTsg76ETU=";
          };
          cargoHash = "sha256-h+sunASiueLa1LZNfTUZlidS1KVh9orxFnTpCcf3s/Y=";
        };

        wrappers = pkgs.rustPlatform.buildRustPackage rec {
          pname = wrappersCrateToml.package.name;
          version = workspaceToml.workspace.package.version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;

          cargoBuildFlags = [ "-p" pname ];
          cargoTestFlags = [ "-p" pname ];
          cargoInstallFlags = [ "-p" pname ];

          OPENSSL_DIR = "${pkgs.openssl.dev}";
          OPENSSL_LIB_DIR = "${pkgs.openssl.out}/lib";
          OPENSSL_INCLUDE_DIR = "${pkgs.openssl.dev}/include";
        };

        portal = pkgs.rustPlatform.buildRustPackage rec {
          pname = portalCrateToml.package.name;
          version = workspaceToml.workspace.package.version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;

          cargoBuildFlags = [ "-p" pname "--bin" portalHostBin ];
          cargoTestFlags = [ "-p" pname "--bin" portalHostBin ];
          cargoInstallFlags = [ "-p" pname "--bin" portalHostBin ];

          OPENSSL_DIR = "${pkgs.openssl.dev}";
          OPENSSL_LIB_DIR = "${pkgs.openssl.out}/lib";
          OPENSSL_INCLUDE_DIR = "${pkgs.openssl.dev}/include";
        };

        cli = pkgs.rustPlatform.buildRustPackage rec {
          pname = "${portalCrateToml.package.name}-cli";
          version = workspaceToml.workspace.package.version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;

          cargoBuildFlags = [ "-p" portalCrateToml.package.name "--bin" pname ];
          cargoTestFlags = [ "-p" portalCrateToml.package.name "--bin" pname ];
          cargoInstallFlags = [ "-p" portalCrateToml.package.name "--bin" pname ];

          OPENSSL_DIR = "${pkgs.openssl.dev}";
          OPENSSL_LIB_DIR = "${pkgs.openssl.out}/lib";
          OPENSSL_INCLUDE_DIR = "${pkgs.openssl.dev}/include";
        };

        ab = pkgs.rustPlatform.buildRustPackage rec {
          pname = abCrateToml.package.name;
          version = workspaceToml.workspace.package.version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;
          cargoBuildFlags = [ "-p" pname ];
          cargoTestFlags = [ "-p" pname ];
        };
      in
      {
        packages = {
          inherit ab wrappers portal cli mdbook-excalidraw;
          default = ab;
        };

        apps = {
          wrappers = {
            type = "app";
            program = "${wrappers}/bin/agent-portal-client";
          };

          wl-paste-wrapper = {
            type = "app";
            program = "${wrappers}/bin/wl-paste";
          };
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            # Rust toolchain (match CI's stable channel)
            rustToolchain

            # Build dependencies
            pkg-config
            openssl

            # Documentation tools
            mdbook
            mdbook-excalidraw

            # Additional tools
            git
          ];

          shellHook = ''
            echo "Agent Box development environment"
            echo "Rust version: $(rustc --version)"
          '';

          # Environment variables for OpenSSL
          OPENSSL_DIR = "${pkgs.openssl.dev}";
          OPENSSL_LIB_DIR = "${pkgs.openssl.out}/lib";
          OPENSSL_INCLUDE_DIR = "${pkgs.openssl.dev}/include";
        };
      }
    ))
    // {
      homeManagerModules = {
        agent-portal = import ./nix/home-manager/agent-portal.nix { inherit self; };
        default = self.homeManagerModules.agent-portal;
      };
    };
}