add integration test for TbtcCbbtc LP on Base

Author: trmid

test/integration/beefy/BeefyBaseAerodromeTbtcCbbtc.t.sol

@@ -0,0 +1,79 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.24;
+
+import { BaseIntegration, IERC20, IERC4626 } from "../BaseIntegration.t.sol";
+
+/// NOTE: must be run with evm version set to "cancun" (this can be done by setting the env var FOUNDRY_PROFILE=cancun)
+
+contract BeefyBaseAerodromeTbtcCbbtcIntegrationTest is BaseIntegration {
+    uint256 fork;
+    uint256 forkBlock = 25127069;
+    uint256 forkBlockTimestamp = 1737043485;
+
+    address internal _beefyWrapper = address(0x917447f8f52E7Db26cE7f52BE2F3fcb4d4D00832);
+
+    address internal _asset = address(0x488d6ea6064eEE9352fdCDB7BC50d98A7fF3AD4E);
+    address internal _assetWhale = address(0x7497B333895C64A56924B293e68a6468963f2A7e);
+    address internal _yieldVault;
+    address internal _mooVault = address(0x64AF54612646CcE0657374226e38B82B8001E674);
+    address internal _mooYieldSource = address(0x6b4a9b0d4d7F363B787594524F351bDe49449EF7);
+
+    /* ============ setup ============ */
+
+    function setUpUnderlyingAsset() public virtual override returns (IERC20 asset, uint8 decimals, uint256 approxAssetUsdExchangeRate) {
+        return (IERC20(_asset), 18, 19_710_000_000e18);
+    }
+
+    function setUpYieldVault() public virtual override returns (IERC4626) {
+        (bool success, bytes memory data) = _beefyWrapper.call(abi.encodeWithSignature("clone(address)", _mooVault));
+        require(success, "beefy vault wrapper failed");
+        (_yieldVault) = abi.decode(data, (address));
+        return IERC4626(_yieldVault);
+    }
+
+    function setUpFork() public virtual override {
+        fork = vm.createFork(vm.rpcUrl("base"), forkBlock);
+        vm.selectFork(fork);
+        vm.warp(forkBlockTimestamp);
+    }
+
+    function beforeSetup() public virtual override {
+        lowGasPriceEstimate = 0.05 gwei; // just L2 gas, we ignore L1 costs for a super low estimate
+        ignoreLoss = true; // loss would occur on the LP token, not the reward contract
+    }
+
+    function afterSetup() public virtual override { }
+
+    /* ============ helpers to override ============ */
+
+    /// @dev The max amount of assets than can be dealt.
+    function maxDeal() public virtual override returns (uint256) {
+        return underlyingAsset.balanceOf(_assetWhale);
+    }
+
+    /// @dev May revert if the amount requested exceeds the amount available to deal.
+    function dealAssets(address to, uint256 amount) public virtual override prankception(_assetWhale) {
+        underlyingAsset.transfer(to, amount);
+    }
+
+    /// @dev Accrues yield by letting time pass and triggering multiple yield accruals
+    function _accrueYield() internal virtual override prankception(_assetWhale) {
+        // yield accrues on deposit / withdraw so we can do a deposit and withdraw to the yield vault directly to trigger some yield accrual
+        uint256 amount = maxDeal() / 100; // some small amount of assets
+        underlyingAsset.approve(_yieldVault, amount);
+        yieldVault.deposit(amount, _assetWhale);
+        vm.warp(block.timestamp + 1 days); // let 1 day pass by
+        uint256 maxRedeem = yieldVault.maxRedeem(_assetWhale);
+        yieldVault.redeem(maxRedeem, _assetWhale, _assetWhale);
+
+        // we also call a deposit directly on the moo vault to ensure it triggers a yield accrual
+        underlyingAsset.approve(_mooVault, amount);
+        (bool success,) = _mooVault.call(abi.encodeWithSignature("deposit(uint256)", amount));
+        assertEq(success, true, "moo vault deposit success");
+    }
+
+    function _simulateLoss() internal virtual override {
+        
+    }
+
+}