build.gradle.kts

plugins {
    alias(libs.plugins.kotlin.jvm)
    `maven-publish`
}

group = "its.development.hypervault"
version = "0.1.0"

kotlin {
    jvmToolchain(11)
}

dependencies {
    // Единственная сторонняя зависимость крипто-ядра (ADR-001).
    implementation(libs.bouncycastle.provider)
    testImplementation(libs.junit)
}

java {
    withSourcesJar()
}

publishing {
    publications {
        create<MavenPublication>("maven") {
            from(components["java"])
            artifactId = "hypervault-crypto"
            pom {
                name.set("hypervault-crypto")
                description.set("Offline cryptographic core of Hypervault: Argon2id, HKDF, AES-256-GCM, HV1 vault format, BIP-32/39, SLIP-10, air-gapped signing.")
                url.set("https://github.com/ITSDevelopmentCore/hypervault-crypto")
                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("https://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }
            }
        }
    }
}