initial commit

Author: Shtoyan

Classes/AssetLoader.#uc

@@ -0,0 +1,10 @@
+class AssetLoader extends Actor
+    notplaceable;
+
+//we need to do this shit or custom font won't load client side
+//also added true KF2 font instead of 'Elegance' font that Zedek had originally
+#exec OBJ LOAD FILE="KF2Font.utx" package="KF2HUD"
+
+defaultproperties
+{
+}

Classes/KF2DamageMessage.uc

@@ -0,0 +1,76 @@
+Class KF2DamageMessage extends LocalMessage;
+
+var localized string HPString;
+var localized float MessageShowTime;
+
+static function string GetNameOf( class<Monster> M )
+{
+	if( Len(M.Default.MenuName)==0 )
+		return string(M.Name);
+	return M.Default.MenuName;
+}
+
+static function ClientReceive(PlayerController P, optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2, optional Object OptionalObject)
+{
+	local KF2HUD H;
+	
+	if( Class<Monster>(OptionalObject)==None || HudBase(P.myHud)==None || (RelatedPRI_1==None && Switch==1) )
+		return;
+	
+	// Change this to the proper class
+	H = KF2HUD(P.myHud);
+    if(H != none)
+    {
+        if (!H.UpdateDamageMessage(OptionalObject,RelatedPRI_1,Switch))
+			H.LocalizedMessage(Default.Class,Switch,RelatedPRI_1,,OptionalObject);
+    }
+
+}
+
+static function float GetLifeTime(int Switch)
+{
+	return default.MessageShowTime;
+}
+
+static function string GetString(
+    optional int Switch,
+    optional PlayerReplicationInfo RelatedPRI_1,
+    optional PlayerReplicationInfo RelatedPRI_2,
+    optional Object OptionalObject
+    )
+{
+	return GetNameOf(Class<Monster>(OptionalObject))@"-"$Switch@Default.HPString;
+}
+
+// Fade color: Green (0-99 damage) > Yellow (100-499 damage) > Red (500-999 damage) > Dark Red (999+ damage).
+static function color GetColor(
+	optional int Switch,
+	optional PlayerReplicationInfo RelatedPRI_1,
+	optional PlayerReplicationInfo RelatedPRI_2
+	)
+{
+	local color C;
+
+	C.A = 255;
+	if( Switch<800 )
+	{
+		C.G = Clamp(512-Switch,0,255);
+		C.R = Clamp((Switch * 2.5f),0,255);
+	}
+	else C.R = Clamp(1256-Switch,150,255);
+	return C;
+}
+
+defaultproperties
+{
+     HPString="HP"
+     MessageShowTime=4.000000
+     bIsConsoleMessage=False
+     bFadeMessage=True
+     DrawColor=(B=0,G=0,R=150)
+     DrawPivot=DP_UpperLeft
+     StackMode=SM_Down
+     PosX=0.020000
+     PosY=0.650000
+     FontSize=-2
+}

Classes/KF2GUILabel.uc

@@ -0,0 +1,72 @@
+class KF2GUILabel extends GUILabel;
+
+var()		byte		AlignMode;
+var()		font		KF2Font;
+var()		bool		bKorean;
+var()		float		KoreanScale;
+
+function bool InternalDraw(Canvas canvas)
+{
+	local float AW, AH, AL, AT, SS, TW, TH;
+	local float TempX, TempY;
+	local Font F;
+	
+	if (bVisible)
+	{
+		AW = ActualWidth();
+		AH = ActualHeight();
+		AL = ActualLeft();
+		AT = ActualTop();
+		
+		SS = canvas.ClipY / 1080.0;
+
+		F = Canvas.Font;
+		
+		// if (default.bKorean)
+		// 	Canvas.Font = Class'FHLang_Core'.default.KoreanFont;
+		// else
+			Canvas.Font = KF2Font;
+
+		Canvas.FontScaleX = 1.0;
+		Canvas.FontScaleY = 1.0;
+		
+		Canvas.TextSize(Caption, TW, TH);
+
+		Canvas.FontScaleX = (AH / TH) * SS;
+		Canvas.FontScaleY = (AH / TH) * SS;
+		
+		if (default.bKorean)
+		{
+			Canvas.FontScaleX *= KoreanScale;
+			Canvas.FontScaleY *= KoreanScale;
+		}
+
+		Canvas.TextSize(Caption, TW, TH);
+		
+		TempY = (AT + (AH*0.5)) - (TH*0.5);
+
+		if (AlignMode == 0)
+			TempX = AL;
+		else if (AlignMode == 1)
+			TempX = ( AL+ (AW*0.5) ) - (TW*0.5);
+		else if (AlignMode == 2)
+			TempX = (AL+AW) - TW;
+
+		Canvas.SetPos(TempX, TempY);
+		Canvas.DrawColor = TextColor;
+		Canvas.DrawText(Caption);
+
+		Canvas.Font = F;
+		Canvas.FontScaleX = 1.0;
+		Canvas.FontScaleY = 1.0;
+	}
+	
+	return true;
+}
+
+defaultproperties
+{
+     KF2Font=Font'KF2HUD.KF2Font'
+     KoreanScale=0.900000
+     OnDraw=KF2GUILabel.InternalDraw
+}