CMakeLists.txt

cmake_minimum_required(VERSION 3.29)

set(KF_VERSION "6.29.0")
project(KHolidays VERSION ${KF_VERSION})

find_package(ECM 6.28.0 REQUIRED NO_MODULE)
set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
set(CMAKE_AUTORCC ON)

include(KDEInstallDirs)
include(KDECMakeSettings)
include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)

include(GenerateExportHeader)
include(ECMGenerateHeaders)
include(CMakePackageConfigHelpers)
include(ECMSetupVersion)
include(ECMPoQmTools)
include(FeatureSummary)
include(ECMCoverageOption)
include(ECMQtDeclareLoggingCategory)
include(KDEGitCommitHooks)
include(ECMGenerateExportHeader)
include(ECMDeprecationSettings)
include(ECMQmlModule)
include(ECMGenerateQDoc)

if(EXISTS "${PROJECT_SOURCE_DIR}/.git/")
    set(GIT_SOURCE_TARBALL TRUE)
endif()

if(GIT_SOURCE_TARBALL)
    set(PRE_COMMIT_INSTALLED FALSE)
    if(${CMAKE_SOURCE_DIR} STREQUAL ${PROJECT_SOURCE_DIR})
        if(EXISTS "${PROJECT_SOURCE_DIR}/.git/hooks/pre-commit")
            file(READ "${PROJECT_SOURCE_DIR}/.git/hooks/pre-commit" FILE_CONTENTS)
            string(
                FIND "${FILE_CONTENTS}"
                "File generated by pre-commit"
                INDEX
            )
            if(${INDEX} GREATER_EQUAL 0)
                set(PRE_COMMIT_INSTALLED TRUE)
            endif()
        endif()
    endif()
    if(NOT ${PRE_COMMIT_INSTALLED})
        function(install_hook executable hook_name)
            message(
                STATUS
                "This module has ${hook_name} support. ${hook_name} binary was found. Installing ${hook_name} hook"
            )
            execute_process(
                COMMAND
                    "${executable}" install -f
                ERROR_QUIET
                RESULT_VARIABLE _precommitresult
                WORKING_DIRECTORY "${PROJECT_SOURCE_DIR}"
            )
            if(_precommitresult EQUAL 0)
                message(STATUS "${hook_name} installed.")
            else()
                message(
                    WARNING
                    "Error during installing ${hook_name} hook: ${executable} project source dir ${PROJECT_SOURCE_DIR}"
                )
                include(KDEGitCommitHooks)
                include(KDEClangFormat)
                kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
            endif()
        endfunction()
        find_program(PREK_EXECUTABLE prek)
        if(PREK_EXECUTABLE)
            install_hook(${PREK_EXECUTABLE} "Prek")
        else()
            find_program(PRE_COMMIT_EXECUTABLE pre-commit)
            if(PRE_COMMIT_EXECUTABLE)
                install_hook(${PRE_COMMIT_EXECUTABLE} "pre-commit")
            else()
                message(WARNING "This module has pre-commit support. pre-commit binary was not found.")
                include(KDEGitCommitHooks)
                include(KDEClangFormat)
                kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
            endif()
        endif()
    endif()
endif()

find_package(FLEX REQUIRED)
set_package_properties(
    FLEX
    PROPERTIES
        URL
            "https://github.com/westes/flex"
        DESCRIPTION
            "Fast Lexical Analyzer"
        TYPE
            REQUIRED
        PURPOSE
            "Required to generate the plan2 parser"
)
find_package(BISON 3.3.2 REQUIRED)
set_package_properties(
    BISON
    PROPERTIES
        URL
            "https://www.gnu.org/software/bison"
        DESCRIPTION
            "general-purpose parser generator"
        TYPE
            REQUIRED
        PURPOSE
            "Required to generate the plan2 parser"
)

set(KHOLIDAYS_LIB_VERSION ${KF_VERSION})
set(EXCLUDE_DEPRECATED_BEFORE_AND_AT
    0
    CACHE STRING
    "Control the range of deprecated API excluded from the build [default=0]."
)

set(kholidays_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kholidays_version.h")
ecm_setup_version(PROJECT VARIABLE_PREFIX KHOLIDAYS
                        VERSION_HEADER "${kholidays_version_header}"
                        PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6HolidaysConfigVersion.cmake"
                        SOVERSION 6
)

########### Find packages ###########
set(REQUIRED_QT_VERSION 6.9.0)
find_package(
    Qt6
    ${REQUIRED_QT_VERSION}
    CONFIG
    REQUIRED
        Core
        Qml
)

remove_definitions(
    -DQT_NO_CAST_FROM_ASCII
    -DQT_NO_CAST_TO_ASCII
)
ecm_set_disabled_deprecation_versions(
    QT 6.11
)

########### Targets ###########
add_subdirectory(src)

if(BUILD_TESTING)
    add_subdirectory(autotests)
endif()

ecm_install_po_files_as_qm(poqm)

########### CMake Config Files ###########
set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Holidays")

configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/KF6HolidaysConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/KF6HolidaysConfig.cmake"
    INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
)

install(
    FILES
        "${CMAKE_CURRENT_BINARY_DIR}/KF6HolidaysConfig.cmake"
        "${CMAKE_CURRENT_BINARY_DIR}/KF6HolidaysConfigVersion.cmake"
    DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
    COMPONENT Devel
)

install(
    EXPORT KF6HolidaysTargets
    DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
    FILE KF6HolidaysTargets.cmake
    NAMESPACE KF6::
)

install(FILES ${kholidays_version_header} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KHolidays COMPONENT Devel)

include(ECMFeatureSummary)
ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)