NanoLimbo/build.gradle.kts at main · Nan1t/NanoLimbo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
plugins {
    id("java")
    alias(libs.plugins.shadow)
    alias(libs.plugins.buildconfig)
}

group = "ua.nanit"
version = "1.13.0"

repositories {
    mavenCentral()
}

dependencies {
    implementation(libs.logback.classic)
    implementation(libs.configurate.yaml)

    implementation(libs.netty.handler)
    implementation(variantOf(libs.netty.transport.native.epoll) { classifier("linux-x86_64") })
    implementation(variantOf(libs.netty.transport.native.epoll) { classifier("linux-aarch_64") })
    implementation(variantOf(libs.netty.transport.native.io.uring) { classifier("linux-x86_64") })
    implementation(variantOf(libs.netty.transport.native.io.uring) { classifier("linux-aarch_64") })
    implementation(variantOf(libs.netty.transport.native.kqueue) { classifier("osx-x86_64") })
    implementation(variantOf(libs.netty.transport.native.kqueue) { classifier("osx-aarch_64") })

    implementation(libs.kyori.adventure.api)
    implementation(libs.kyori.adventure.text.serializer.gson)
    implementation(libs.kyori.adventure.text.serializer.legacy)
    implementation(libs.kyori.adventure.text.serializer.json.legacy.impl)
    implementation(libs.kyori.adventure.text.serializer.plain)
    implementation(libs.kyori.adventure.text.serializer.minimessage)
    implementation(libs.kyori.adventure.nbt)

    implementation(libs.gson)

    compileOnly(libs.lombok)
    annotationProcessor(libs.lombok)
}

tasks {
    compileJava {
        options.encoding = "UTF-8"
    }

    shadowJar {
        from("LICENSE")

        archiveClassifier.set("")
        archiveVersion.set("")

        manifest {
            attributes(
                mapOf(
                    "Main-Class" to "ua.nanit.limbo.NanoLimbo"
                )
            )
        }

        minimize {
            exclude(dependency("ch.qos.logback:logback-classic:.*:.*"))
        }
    }

    build {
        dependsOn(shadowJar)
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

buildConfig {
    className("BuildConfig")
    packageName("ua.nanit.limbo")
    buildConfigField("LIMBO_VERSION", provider { "${project.version}" })
}