OCCT static libraries build directories

[petrasvestartas]

Hi,

I am trying compare build directories of OCCT they are different in each operating system.
What is the directory of mac intel x86 ? I do not have such computer.

I hardcode each path for cmake, is there a way to set one common folder for all OS?

# Set platform-specific hardcoded paths for OCCT libraries
if(NOT OCCT_LIB_DIR)
    if(WIN32)
        set(OCCT_LIB_DIR "${OCCT_BUILD_DIR}/win64/vc14/lib" CACHE PATH "Path to OCCT libraries" FORCE)
    elseif(APPLE)
        if(CMAKE_SYSTEM_PROCESSOR STREQUAL "arm64")
            set(OCCT_LIB_DIR "${OCCT_BUILD_DIR}/mac64/clang/lib" CACHE PATH "Path to OCCT libraries" FORCE)
        else()
            set(OCCT_LIB_DIR "${OCCT_BUILD_DIR}/macx86_64/clang/lib" CACHE PATH "Path to OCCT libraries" FORCE) 
        endif()
    else() # Linux
        set(OCCT_LIB_DIR "${OCCT_BUILD_DIR}/lin64/gcc/lib" CACHE PATH "Path to OCCT libraries" FORCE)
    endif()
endif()

message(STATUS "---------------------- OCCT_LIB_DIR: ${OCCT_LIB_DIR}")
message(STATUS "---------------------- OCCT_INCLUDE_DIR: ${OCCT_INCLUDE_DIR}")

# Generate the library targets list using OCCT_LIB_DIR already set for each platform
set(OCCT_LIB_TARGETS "")
set(OCCT_MODULES TKBool TKFillet TKOffset TKFeat TKPrim TKBO TKMesh TKHLR TKShHealing TKTopAlgo TKGeomAlgo TKBRep TKGeomBase TKG3d TKG2d TKMath TKernel)
foreach(MODULE ${OCCT_MODULES})
    list(APPEND OCCT_LIB_TARGETS "${OCCT_LIB_DIR}/${LIB_PREFIX}${MODULE}${LIB_EXT}")
endforeach()

# Always create OCCT targets for dependency tracking
add_custom_target(occt_ext)
set(OCCT_TARGET occt_ext)

if(NOT OCCT_ALREADY_BUILT)
    ExternalProject_Add(
        occt_download
        URL https://github.com/Open-Cascade-SAS/OCCT/archive/refs/tags/V7_9_0.zip
        PREFIX ${OCCT_PREFIX}
        SOURCE_DIR ${OCCT_SRC_DIR}
        BINARY_DIR ${OCCT_BUILD_DIR}
        CMAKE_ARGS
            -DCMAKE_INSTALL_PREFIX=${OCCT_INSTALL_DIR}
            -DCMAKE_BUILD_TYPE=Release
            -DBUILD_LIBRARY_TYPE=Static
            -DBUILD_MODULE_Draw=OFF
            -DBUILD_MODULE_ApplicationFramework=OFF
            -DBUILD_MODULE_DataExchange=OFF
            -DBUILD_MODULE_Visualization=OFF
            -DBUILD_SAMPLES_QT=OFF
            -DBUILD_MODULE_Modeling=ON
            -DBUILD_USE_PCH=OFF
        BUILD_COMMAND ${CMAKE_COMMAND} --build . --config Release -j2
        INSTALL_COMMAND ${CMAKE_COMMAND} --install . --config Release --component Development
        BUILD_BYPRODUCTS ${OCCT_LIB_TARGETS}
    )
    
    add_dependencies(external_downloads occt_download)
    add_dependencies(occt_ext occt_download)
    set(OCCT_ALREADY_BUILT TRUE CACHE BOOL "Flag to indicate if OCCT has been built" FORCE)
endif()

[dpasukhi]

You can specify the installation folder by providing them as an parameters for configuration

Available:
INSTALL_DIR_BIN (example win64/clang/bin)
INSTALL_DIR_LIB (example win64/clang/lib)
INSTALL_DIR_INCLUDE (example inc)

Also you can specify LAYOUT (Windows or Unix). Unix is common one
INSTALL_DIR_LAYOUT (example Windows)

[petrasvestartas]

I tried to set it up like that but occt/install/lib folder after building is empty

    ExternalProject_Add(
        occt_download
        URL https://github.com/Open-Cascade-SAS/OCCT/archive/refs/tags/V7_9_0.zip
        PREFIX ${OCCT_PREFIX}
        SOURCE_DIR ${OCCT_SRC_DIR}
        BINARY_DIR ${OCCT_BUILD_DIR}
        CMAKE_ARGS
            -DCMAKE_INSTALL_PREFIX=${OCCT_INSTALL_DIR}
            # Use OCCT-specific install directory variables
            -DINSTALL_DIR_LIB=lib # static libraries path
            -DINSTALL_DIR_INCLUDE=include # header files path
            -DINSTALL_DIR_LAYOUT=Unix # layout of the install directory
            # Other build options
            -DCMAKE_BUILD_TYPE=Release
            -DBUILD_LIBRARY_TYPE=Static
            -DBUILD_MODULE_Draw=OFF
            -DBUILD_MODULE_ApplicationFramework=OFF
            -DBUILD_MODULE_DataExchange=OFF
            -DBUILD_MODULE_Visualization=OFF
            -DBUILD_SAMPLES_QT=OFF
            -DBUILD_USE_PCH=OFF
        BUILD_COMMAND ${CMAKE_COMMAND} --build . --config Release -j2
        INSTALL_COMMAND ${CMAKE_COMMAND} --install . --config Release --component Development
        BUILD_BYPRODUCTS ${OCCT_LIB_TARGETS}
    )

[dpasukhi]

Need not only build "." But make installation.

[petrasvestartas]

Could please explain more? :)

[petrasvestartas]

I think worked on ubuntu, i will test on other system.

[petrasvestartas]

This is the working example if anyone will struggle with this for Windows, Mac (arm and intel) and Linux:

cmake_minimum_required(VERSION 3.15)
project(compas_occt LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

include(ExternalProject)
find_package(Python 3.8 REQUIRED COMPONENTS Interpreter Development.Module Development.SABIModule)
find_package(nanobind CONFIG REQUIRED)
find_package(Threads REQUIRED)

# ------------------------------------------------------------------------------
# Eigen (header-only library)
# ------------------------------------------------------------------------------
set(EIGEN_DIR "${CMAKE_CURRENT_SOURCE_DIR}/external/eigen")
file(MAKE_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/external") # Create directories if they don't exist
add_custom_target(eigen_ext) # Create a target for Eigen tracking
set(EIGEN_TARGET eigen_ext)

if(NOT EXISTS "${EIGEN_DIR}/Eigen")
    ExternalProject_Add(
        eigen_download
        URL https://gitlab.com/libeigen/eigen/-/archive/3.4.0/eigen-3.4.0.zip
        PREFIX ${CMAKE_BINARY_DIR}/deps/eigen
        SOURCE_DIR ${EIGEN_DIR}
        CONFIGURE_COMMAND ""
        BUILD_COMMAND ""
        INSTALL_COMMAND ""
        TEST_COMMAND ""
    )
    add_dependencies(eigen_ext eigen_download)
endif()

message(STATUS "---------------------- Eigen: ${EIGEN_DIR}")

# ------------------------------------------------------------------------------
# OCCT
# ------------------------------------------------------------------------------
set(CMAKE_DEPS_DIR ${CMAKE_BINARY_DIR}/deps)
set(OCCT_PREFIX ${CMAKE_DEPS_DIR}/occt) # Create needed directories
file(MAKE_DIRECTORY ${CMAKE_DEPS_DIR})
set(OCCT_SRC_DIR ${OCCT_PREFIX}/src/occt)
set(OCCT_BUILD_DIR ${OCCT_PREFIX}/src/occt-build)
set(OCCT_INSTALL_DIR ${OCCT_PREFIX}/install) # Use the same custom install path as specified in ExternalProject_Add
set(OCCT_INCLUDE_DIR "${OCCT_INSTALL_DIR}/my_include" CACHE PATH "Path to OCCT headers" FORCE) # Use the same custom include path as specified in ExternalProject_Add
set(OCCT_LIB_DIR "${OCCT_INSTALL_DIR}/my_static_libs" CACHE PATH "Path to OCCT libraries" FORCE)

message(STATUS "---------------------- OCCT_INCLUDE_DIR: ${OCCT_INCLUDE_DIR}")
message(STATUS "---------------------- OCCT_LIB_DIR: ${OCCT_LIB_DIR}")

if(WIN32)
    set(LIB_PREFIX "")
    set(LIB_EXT ".lib")
else()
    set(LIB_PREFIX "lib")
    set(LIB_EXT ".a")
endif()

# Generate the library targets list using OCCT_LIB_DIR already set for each platform
set(OCCT_LIB_TARGETS "")
set(OCCT_MODULES TKBool TKFillet TKOffset TKFeat TKPrim TKBO TKMesh TKHLR TKShHealing TKTopAlgo TKGeomAlgo TKBRep TKGeomBase TKG3d TKG2d TKMath TKernel)
foreach(MODULE ${OCCT_MODULES})
    list(APPEND OCCT_LIB_TARGETS "${OCCT_LIB_DIR}/${LIB_PREFIX}${MODULE}${LIB_EXT}")
endforeach()

# Always create OCCT targets for dependency tracking
add_custom_target(occt_ext)
set(OCCT_TARGET occt_ext)

if(NOT EXISTS "${OCCT_INSTALL_DIR}/my_include" OR NOT EXISTS "${OCCT_INSTALL_DIR}/my_static_libs")
    ExternalProject_Add(
        occt_download
        URL https://github.com/Open-Cascade-SAS/OCCT/archive/refs/tags/V7_9_0.zip
        PREFIX ${OCCT_PREFIX}
        SOURCE_DIR ${OCCT_SRC_DIR}
        BINARY_DIR ${OCCT_BUILD_DIR}
        CMAKE_ARGS
            -DCMAKE_INSTALL_PREFIX=${OCCT_INSTALL_DIR}
            # Use OCCT-specific install directory variables without quotes
            -DINSTALL_DIR_LIB=my_static_libs 
            -DINSTALL_DIR_INCLUDE=my_include 
            -DINSTALL_DIR_LAYOUT=Unix
            # Other build options
            -DCMAKE_BUILD_TYPE=Release
            -DBUILD_LIBRARY_TYPE=Static
            -DBUILD_MODULE_Draw=OFF
            -DBUILD_MODULE_ApplicationFramework=OFF
            -DBUILD_MODULE_DataExchange=OFF
            -DBUILD_MODULE_Visualization=OFF
            -DBUILD_SAMPLES_QT=OFF
            -DBUILD_USE_PCH=ON
        # Must build AND install the libraries to the custom location
        BUILD_COMMAND ${CMAKE_COMMAND} --build . --config Release # -j4
        INSTALL_COMMAND ${CMAKE_COMMAND} --install . --config Release
        BUILD_BYPRODUCTS ${OCCT_LIB_TARGETS}
    )
    
    add_dependencies(occt_ext occt_download)
endif()

# ------------------------------------------------------------------------------
# Build nanobind Python modules
# ------------------------------------------------------------------------------

function(add_nanobind_module module_name source_file)
    nanobind_add_module(${module_name} ${source_file})
    target_include_directories(${module_name} SYSTEM PRIVATE ${EIGEN_DIR} ${OCCT_INCLUDE_DIR})
    add_dependencies(${module_name} ${EIGEN_TARGET} ${OCCT_TARGET})
    target_link_libraries(${module_name} PRIVATE ${OCCT_LIB_TARGETS})
    install(TARGETS ${module_name} LIBRARY DESTINATION compas_occt)
endfunction()

add_nanobind_module(_primitives src/primitives.cpp)
add_nanobind_module(_curves src/curves.cpp)