Build LLDB as part of wasi-sdk

This is intended to provide a known-good build of LLDB with wasm plugin
support which can exist alongside the rest of the LLVM distribution
provided by wasi-sdk.

To make LLDB reasonably usable it additionally needs libedit for the
CLI, so that's setup/installed here too.

Author: alexcrichton

ci/docker/Dockerfile

@@ -12,7 +12,8 @@ RUN dnf install -y \
   python3 \
   git \
   unzip \
-  cmake
+  cmake \
+  ncurses-devel
 
 COPY ./install-ccache.sh .
 RUN ./install-ccache.sh

cmake/wasi-sdk-toolchain.cmake

@@ -5,6 +5,15 @@ set(LLVM_CMAKE_FLAGS "" CACHE STRING "Extra cmake flags to pass to LLVM's build"
 set(RUST_TARGET "" CACHE STRING "Target to build Rust code for, if not the host")
 set(WASI_SDK_ARTIFACT "" CACHE STRING "Name of the wasi-sdk artifact being produced")
 
+set(LLDB_DEFAULT ON)
+# Currently LLDB effectively requires libedit to be usable, and building libedit
+# on Windows isn't easy due to usage of `./configure`. Disable LLDB entirely on
+# Windows for now.
+if(WIN32)
+  set(LLDB_DEFAULT OFF)
+endif()
+option(LLDB "Include a build of LLDB" ${LLDB_DEFAULT})
+
 string(REGEX REPLACE "[ ]+" ";" llvm_cmake_flags_list "${LLVM_CMAKE_FLAGS}")
 
 set(wasi_tmp_install ${CMAKE_CURRENT_BINARY_DIR}/install)
@@ -72,6 +81,58 @@ if(NOT WIN32)
   list(APPEND tools LLVM clang-cpp)
 endif()
 
+# Configure/add LLDB if requested.
+#
+# Note that LLDB depends on `libedit` which is more-or-less required to get a
+# reasonable command-line experience, so this is built custom here to ensure
+# that it's available for LLDB.
+if(LLDB)
+  include(ProcessorCount)
+  ProcessorCount(nproc)
+  find_program(MAKE_EXECUTABLE make REQUIRED)
+
+  ExternalProject_Add(libedit
+    URL https://thrysoee.dk/editline/libedit-20251016-3.1.tar.gz
+    URL_HASH SHA256=21362b00653bbfc1c71f71a7578da66b5b5203559d43134d2dd7719e313ce041
+
+    # Without this the build system tries to find and use `aclocal-1.18` where
+    # with this it doesn't so turn this on.
+    DOWNLOAD_EXTRACT_TIMESTAMP ON
+
+    CONFIGURE_COMMAND
+      <SOURCE_DIR>/configure
+        --prefix=${CMAKE_INSTALL_PREFIX}
+        --enable-pic
+        --disable-examples
+        CC=${CMAKE_C_COMPILER}
+    BUILD_COMMAND
+      ${MAKE_EXECUTABLE} -j${nproc}
+
+    USES_TERMINAL_CONFIGURE ON
+    USES_TERMINAL_BUILD ON
+    USES_TERMINAL_INSTALL ON
+  )
+
+  list(APPEND projects lldb)
+  list(APPEND tools lldb liblldb)
+  list(APPEND default_cmake_args
+    -DLLDB_INCLUDE_TESTS=OFF
+    -DLLDB_INCLUDE_UNITTESTS=OFF
+    -DLLDB_ENABLE_SWIG=OFF
+    -DLLDB_ENABLE_CURSES=OFF
+    -DLLDB_ENABLE_LZMA=OFF
+    -DLLDB_ENABLE_LUA=OFF
+    -DLLDB_ENABLE_PYTHON=OFF
+    -DLLDB_ENABLE_LIBXML2=OFF
+    -DLLDB_ENABLE_FBSDVMCORE=OFF
+    -DLLDB_ENABLE_LINUXPTY=OFF
+    -DLLDB_ENABLE_LIBEDIT=ON
+    -DLibEdit_ROOT=${CMAKE_INSTALL_PREFIX}
+  )
+else()
+  add_custom_target(libedit)
+endif()
+
 list(TRANSFORM tools PREPEND --target= OUTPUT_VARIABLE build_targets)
 list(TRANSFORM tools PREPEND --target=install- OUTPUT_VARIABLE install_targets)
 
@@ -109,6 +170,7 @@ ExternalProject_Add(llvm-build
 )
 
 add_custom_target(build ALL DEPENDS llvm-build)
+ExternalProject_Add_StepDependencies(llvm-build configure libedit)
 
 # Installation target for this outer project for installing the toolchain to the
 # system.