Justfile

project   := "TabBuddy"
scheme    := "TabBuddy"
config    := "Release"
export_dir := "build/export"
archive   := "build/TabBuddy.xcarchive"

# Run the app in debug mode
run:
    xcodebuild -project {{project}}.xcodeproj \
               -scheme {{scheme}} \
               -configuration Debug \
               -destination 'platform=macOS' \
               build
    open "$(xcodebuild -project {{project}}.xcodeproj \
                       -scheme {{scheme}} \
                       -configuration Debug \
                       -showBuildSettings 2>/dev/null \
           | awk '/BUILT_PRODUCTS_DIR/{dir=$3} /WRAPPER_NAME/{name=$3} END{print dir"/"name}')"

# Archive and export the app for distribution
release: _archive _export
    @echo "Done → {{export_dir}}/{{project}}.app"

# Build an xcarchive
_archive:
    mkdir -p build
    xcodebuild archive \
               -project {{project}}.xcodeproj \
               -scheme {{scheme}} \
               -configuration {{config}} \
               -archivePath {{archive}}

# Export the archive
_export:
    mkdir -p {{export_dir}}
    xcodebuild -exportArchive \
               -archivePath {{archive}} \
               -exportPath {{export_dir}} \
               -exportOptionsPlist ExportOptions.plist

# Clean build artifacts
clean:
    rm -rf build
    xcodebuild clean -project {{project}}.xcodeproj -scheme {{scheme}}