Added tests for os_version_minor

Signed-off-by: Victor Moene <[email protected]>

Author: victormlg

tests/acceptance/01_vars/01_basic/os_version_minor.cf

@@ -0,0 +1,74 @@
+body common control
+{
+  bundlesequence => { "test", "check" };
+}
+
+bundle agent test
+{
+
+  vars:
+    # Platforms to test
+    any::
+      "platforms"
+        slist => { "debian", "ubuntu", "redhat", "rhel", "centos", "fedora",
+                   "aix", "hpux", "suse", "opensuse", "opensuse_leap", "sles",
+                   "solaris", "sunos", "windows", "freebsd", "macos" };
+
+
+    # Regex matching current platforms OS-class with version numbers
+    !solaris&!sunos::
+      "class_regex"
+        string => format("^(%s)_[0-9]+_[0-9]+$", join("|", "platforms"));
+    solaris|sunos::
+      "class_regex"
+        string => format("^(%s)_[0-9]+$", join("|", "platforms"));
+
+    # Regex to extract minor version number from OS-class
+    # Edge cases:
+    #  - On Solaris/SunOS minor version comes second
+    #    E.g. Solaris 11 has class "solaris_5_11"
+    any::
+      "extract_regex"
+        string => ifelse("solaris|sunos", "^[a-z]+_([0-9]+)$",
+                         "opensuse_leap", "^[a-z_]+_[0-9]+_([0-9]+$)",
+                                          "^[a-z]+_[0-9]+_([0-9]+$)");
+
+    # Find OS-class with version numbers using regex
+    any::
+      "os_class"
+        string => nth(classesmatching("$(class_regex)"), "0");
+
+    # Get extracted minor version number
+    any::
+      "expected"
+        string => nth("version_number", "1");
+
+  classes:
+    any::
+      "regextract_success"
+        expression => regextract("$(extract_regex)", "$(os_class)", "version_number");
+}
+
+bundle agent check
+{
+  vars:
+    any::
+      "defined_classes"
+        slist => classesmatching(".*");
+
+  classes:
+    any::
+      "passed"
+        expression => strcmp("$(test.expected)", "$(sys.os_version_minor)");
+
+  reports:
+    DEBUG::
+      "Version number extracted from class: $(test.os_class)";
+      "Defined classes: $(defined_classes)";
+      "$(this.promise_filename) Expected: $(test.expected)";
+      "$(this.promise_filename) Found: $(sys.os_version_minor)";
+    passed::
+      "$(this.promise_filename) Pass";
+    !passed::
+      "$(this.promise_filename) FAIL";
+}

tests/acceptance/01_vars/01_basic/os_version_minor_simple.cf

@@ -0,0 +1,40 @@
+body common control
+{
+  bundlesequence => { "check" };
+}
+
+bundle agent check
+{
+  classes:
+    ubuntu_20_04|ubuntu_22_04|ubuntu_24_04::
+      "ok"
+        if => strcmp("$(sys.os_version_minor)", "04");
+      "not_ok"
+        if => not(strcmp("$(sys.os_version_minor)", "04"));
+
+    debian_12_11::
+      "ok"
+        if => strcmp("$(sys.os_version_minor)", "11");
+      "not_ok"
+        if => not(strcmp("$(sys.os_version_minor)", "11"));
+
+    centos_7_6::
+      "ok"
+        if => strcmp("$(sys.os_version_minor)", "6");
+      "not_ok"
+        if => not(strcmp("$(sys.os_version_minor)", "6"));
+
+    redhat_8_10::
+      "ok"
+        if => strcmp("$(sys.os_version_minor)", "10");
+      "not_ok"
+        if => not(strcmp("$(sys.os_version_minor)", "10"));
+
+  reports:
+    DEBUG::
+      "$(sys.os_name_human)_$(sys.os_version_major)_$(sys.os_version_minor)";
+    ok.!not_ok::
+      "$(this.promise_filename) Pass";
+    !ok|not_ok::
+      "$(this.promise_filename) FAIL";
+}