clan-core/flake.nix at main · clan-lol/clan-core · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
{
  description = "clan.lol base operating system";

  inputs = {
    nixpkgs.url = "https://nixos.org/channels/nixpkgs-unstable/nixexprs.tar.xz";

    nix-darwin.url = "github:nix-darwin/nix-darwin";
    nix-darwin.inputs.nixpkgs.follows = "nixpkgs";

    flake-parts.url = "github:hercules-ci/flake-parts";
    flake-parts.inputs.nixpkgs-lib.follows = "nixpkgs";

    disko.url = "github:nix-community/disko";
    disko.inputs.nixpkgs.follows = "nixpkgs";

    sops-nix.url = "github:Mic92/sops-nix";
    sops-nix.inputs.nixpkgs.follows = "nixpkgs";

    systems.url = "github:nix-systems/default/future-26.11";

    treefmt-nix.url = "github:numtide/treefmt-nix";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";

    nix-select.url = "https://git.clan.lol/clan/nix-select/archive/main.tar.gz";

    data-mesher = {
      url = "https://git.clan.lol/clan/data-mesher/archive/main.tar.gz";
      inputs = {
        flake-parts.follows = "flake-parts";
        nixpkgs.follows = "nixpkgs";
        treefmt-nix.follows = "treefmt-nix";
      };
    };

  };

  outputs =
    inputs@{
      nixpkgs,
      systems,
      flake-parts,
      ...
    }:
    let
      inherit (nixpkgs.lib)
        filter
        optional
        pathExists
        ;
    in
    flake-parts.lib.mkFlake
      {
        inherit inputs;
      }
      (
        {
          lib,
          flake-parts-lib,
          ...
        }:
        {
          debug = true;
          clan = {
            meta.name = "clan-core";
            inventory = {
              machines = {
                "test-darwin-machine" = {
                  machineClass = "darwin";
                };
              };
            };
            # Allows downstream users to inject "unsupported" nixpkgs versions
            checks.minNixpkgsVersion.ignore = true;
          };
          systems = import systems;
          imports = [
            flake-parts.flakeModules.modules
          ]
          ++
            # only importing existing paths allows to minimize the flake for test
            # by removing files
            filter pathExists [
              ./checks/flake-module.nix
              ./clanServices/flake-module.nix
              ./devShell.nix
              ./apps.nix
              ./docs/flake-module.nix
              ./site/flake-module.nix
              ./flakeModules/demo_iso.nix
              ./flakeModules/flake-module.nix
              ./lib/filter-clan-core/flake-module.nix
              ./lib/flake-module.nix
              ./lib/flake-parts/clan-nixos-test.nix
              ./modules/flake-module.nix
              ./nixosModules/clanCore/vars/flake-module.nix
              ./nixosModules/flake-module.nix
              ./pkgs/flake-module.nix
              ./templates/flake-module.nix
            ]
          ++ lib.optional (pathExists ./flakeModules/clan.nix) (
            import ./flakeModules/clan.nix {
              clanLib = inputs.self.lib;
              coreInputs = inputs.self.inputs;
              coreModules = inputs.self.modules;
              inherit flake-parts-lib;
            }
          )

          # Make treefmt-nix optional
          # This only works if you set inputs.clan-core.inputs.treefmt-nix.follows
          # to a non-empty input that doesn't export a flakeModule
          ++ optional (pathExists ./formatter.nix && inputs.treefmt-nix ? flakeModule) ./formatter.nix;
        }
      );
}