feat: Port Module Changes and Port Order Example (#219)

* Port Module changes

* Add example for port order

* Cleanup comments

* Add new line

* Add check if both uuid and name are provided, give warning

* Update with new filters param

* More changes

* Remove comments

* Remove duplicate code

* Minor changes

* Add variable name

* Address PR comments

* Remove extra lines

* Remove extra lines

Author: d-bhola

examples/port-order-with-create-connection/README.md

@@ -0,0 +1,13 @@
+# Fabric Port to Fabric Public Service Profile Connection
+
+This example shows how to leverage the [Fabric Port Connection Module](https://registry.terraform.io/modules/equinix/fabric/equinix/latest/submodules/port-connection)
+to create a Fabric Connection from a Fabric Port to Fabric Public Service Profile.
+
+It leverages the Equinix Terraform Provider, equinix_fabric_port Terraform resource, equinix_fabric_port Terraform datasource and the Fabric Port Connection
+Module to setup the connection based on the parameters you have provided to this example; or based on the pattern
+you see used in this example it will allow you to create a more specific use case for your own needs.
+
+See example usage below for details on how to use this example.
+
+<!-- BEGIN_TF_DOCS -->
+<!-- END_TF_DOCS -->

examples/port-order-with-create-connection/main.tf

@@ -0,0 +1,103 @@
+provider "equinix" {
+  client_id     = var.equinix_client_id
+  client_secret = var.equinix_client_secret
+}
+
+resource "equinix_fabric_port" "order" {
+  type = "XF_PORT"
+  physical_ports_speed = var.physical_ports_speed
+  connectivity_source_type = var.connectivity_source_type
+  project = {
+    project_id = var.project_id
+  }
+  account = {
+    account_number = var.account_number
+  }
+  location = {
+    metro_code = var.metro_code
+  }
+  physical_ports_type = var.physical_ports_type
+  demarcation_point_ibx = var.demarcation_point_ibx
+  redundancy = {
+    priority = var.priority
+  }
+  encapsulation = {
+    type = var.encapsulation_type
+    tag_protocol_id = var.tag_protocol_id
+  }
+  lag_enabled = var.lag_enabled
+  settings = {
+    package_type = var.package_type
+    shared_port_type = var.shared_port_type
+  }
+  physical_ports = [
+    {
+      type = var.type
+      demarcation_point = {
+        cage_unique_space_id = var.cage_unique_space_id
+        cabinet_unique_space_id = var.cabinet_unique_space_id
+        connector_type = var.connector_type
+        patch_panel = var.patch_panel
+        ibx = var.ibx
+      }
+    }
+  ]
+  notifications = [
+    {
+      type = "TECHNICAL"
+      registered_users = [
+        var.registered_user
+      ]
+    },
+    {
+      type = "NOTIFICATION"
+      registered_users = [
+        var.registered_user
+      ]
+    }
+  ]
+  physical_ports_count = var.physical_ports_count
+}
+
+resource "time_sleep" "wait_for_activation" {
+  depends_on      = [equinix_fabric_port.order]
+  create_duration = "5m"
+}
+
+data "equinix_fabric_port" "check_active" {
+  depends_on = [time_sleep.wait_for_activation]
+  uuid       = equinix_fabric_port.order.id
+}
+
+resource "null_resource" "port_active_check" {
+  depends_on = [data.equinix_fabric_port.check_active]
+
+  lifecycle {
+    precondition {
+      condition     = data.equinix_fabric_port.check_active.state == "ACTIVE"
+      error_message = "Port must be ACTIVE (current: ${data.equinix_fabric_port.check_active.state})"
+    }
+  }
+}
+
+module "create_port_2_public_sp_connection" {
+  depends_on = [null_resource.port_active_check]
+  source = "../../modules/port-connection"
+
+  connection_name       = var.connection_name
+  connection_type       = var.connection_type
+  notifications_type    = var.notifications_type
+  notifications_emails  = var.notifications_emails
+  bandwidth             = var.bandwidth
+  purchase_order_number = var.purchase_order_number
+
+  # A-side
+  aside_port_uuid = equinix_fabric_port.order.id
+  aside_vlan_tag  = var.aside_vlan_tag
+
+  # Z-side
+  zside_ap_type         = var.zside_ap_type
+  zside_ap_profile_type = var.zside_ap_profile_type
+  zside_location        = var.zside_location
+  zside_sp_name         = var.zside_sp_name
+}

examples/port-order-with-create-connection/outputs.tf

@@ -0,0 +1,9 @@
+output "port_uuid" {
+  value = equinix_fabric_port.order.id
+}
+output "port_state" {
+  value = data.equinix_fabric_port.check_active.state
+}
+output "public_sp_connection_id" {
+  value = module.create_port_2_public_sp_connection.primary_connection_id
+}

examples/port-order-with-create-connection/terraform.tfvars.example

@@ -0,0 +1,34 @@
+equinix_client_id      = "MyEquinixClientId"
+equinix_client_secret  = "MyEquinixSecret"
+
+physical_ports_type         = "1000BASE_LX"
+physical_ports_speed        = 1000
+connectivity_source_type    = "COLO"
+account_number              = "1234567"
+metro_code                  = "SV"
+ibx                         = "SV1"
+demarcation_point_ibx       = "SV1"
+cage_unique_space_id        = "CAGE-001"
+cabinet_unique_space_id     = "CAB-001"
+patch_panel                 = "PP-01"
+project_id                  = "project-001"
+registered_user             = "user@example.com"
+physical_ports_count        = 1
+tag_protocol_id             = "0x8100"
+connector_type              = "SC"
+package_type                = "STANDARD"
+priority                    = "PRIMARY"
+encapsulation_type          = "DOT1Q"
+
+connection_name       = "PortOrderCreateConnection"
+connection_type       = "EVPL_VC"
+notifications_type    = "ALL"
+notifications_emails  = ["example@equinix.com"]
+bandwidth             = 50
+purchase_order_number = "PO-123456"
+aside_vlan_tag        = 2000
+
+zside_ap_type         = "SP"
+zside_ap_profile_type = "L2_PROFILE"
+zside_location        = "SV"
+zside_sp_name         = "Test-SP"

examples/port-order-with-create-connection/variables.tf

@@ -0,0 +1,145 @@
+variable "equinix_client_id" {
+  description = "Equinix client ID (consumer key), obtained after registering app in the developer platform"
+  type        = string
+  sensitive   = true
+}
+variable "equinix_client_secret" {
+  description = "Equinix client secret ID (consumer secret), obtained after registering app in the developer platform"
+  type        = string
+  sensitive   = true
+}
+variable "connection_name" {
+  description = "Connection name. An alpha-numeric 24 characters string which can include only hyphens and underscores"
+  type        = string
+}
+variable "connection_type" {
+  description = "Defines the connection type like VG_VC, EVPL_VC, EPL_VC, EC_VC, IP_VC, ACCESS_EPL_VC"
+  type        = string
+}
+variable "notifications_type" {
+  description = "Notification Type - ALL is the only type currently supported"
+  type        = string
+  default     = "ALL"
+}
+variable "notifications_emails" {
+  description = "Array of contact emails"
+  type        = list(string)
+}
+variable "bandwidth" {
+  description = "Connection bandwidth in Mbps"
+  type        = number
+}
+variable "purchase_order_number" {
+  description = "Order number"
+  type        = string
+  default     = ""
+}
+variable "aside_vlan_tag" {
+  description = "Vlan Tag information, outer vlanSTag for QINQ connections"
+  type        = string
+}
+variable "zside_ap_type" {
+  description = "Access point type - COLO, VD, VG, SP, IGW, SUBNET, GW"
+  type        = string
+}
+variable "zside_ap_profile_type" {
+  description = "Service profile type - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE"
+  type        = string
+}
+variable "zside_location" {
+  description = "Access point metro code"
+  type        = string
+}
+variable "zside_sp_name" {
+  description = "Equinix Service Profile Name"
+  type        = string
+}
+variable "physical_ports_type" {
+  description = "Physical ports type"
+  type        = string
+  default     = "1000BASE_LX"
+}
+variable "physical_ports_speed" {
+  description = "Physical ports speed"
+  type        = number
+  default     = 1000
+}
+variable "connectivity_source_type" {
+  description = "Connectivity source type"
+  type        = string
+  default     = "COLO"
+}
+variable "account_number" {
+  description = "Account number"
+  type        = string
+}
+variable "metro_code" {
+  description = "Metro code"
+  type        = string
+}
+variable "ibx" {
+  description = "IBX"
+  type        = string
+}
+variable "demarcation_point_ibx" {
+  description = "Demarcation point IBX"
+  type        = string
+}
+variable "cage_unique_space_id" {
+  description = "Cage unique space ID"
+  type        = string
+}
+variable "cabinet_unique_space_id" {
+  description = "Cabinet unique space ID"
+  type        = string
+}
+variable "patch_panel" {
+  description = "Patch panel"
+  type        = string
+}
+variable "project_id" {
+  description = "Project ID"
+  type        = string
+}
+variable "registered_user" {
+  description = "Registered user for notifications"
+  type        = string
+}
+variable "physical_ports_count" {
+  description = "Physical ports count"
+  type        = number
+  default     = 1
+}
+variable "tag_protocol_id" {
+    description = "Tag protocol ID"
+    type        = string
+}
+variable "connector_type" {
+    description = "Connector type"
+    type        = string
+}
+variable "package_type" {
+    description = "Package type"
+    type        = string
+    default     = "STANDARD"
+}
+variable "priority" {
+    description = "Redundancy priority"
+    type        = string
+}
+variable "encapsulation_type" {
+    description = "Encapsulation type"
+    type        = string
+}
+variable "lag_enabled" {
+    description = "LAG enabled"
+    type        = bool
+}
+variable "shared_port_type" {
+    description = "Shared port type"
+    type        = bool
+}
+variable "type" {
+    description = "Physical port type"
+    type        = string
+}

examples/port-order-with-create-connection/versions.tf

@@ -0,0 +1,9 @@
+terraform {
+  required_version = ">= 1.5.4"
+  required_providers {
+    equinix = {
+      source  = "equinix/equinix"
+      version = ">= 4.9.0"
+    }
+  }
+}

modules/port-connection/main.tf

@@ -1,13 +1,17 @@
 data "equinix_fabric_ports" "aside_port" {
-  filters {
-    name = var.aside_port_name
+  filter {
+    property = var.aside_port_name != "" ? "/name" : "/uuid"
+    operator = "="
+    value    = var.aside_port_name != "" ? var.aside_port_name : var.aside_port_uuid
   }
 }
 
 data "equinix_fabric_ports" "aside_secondary_port" {
   count = var.aside_secondary_port_name != "" ? 1 : 0
-  filters {
-    name = var.aside_secondary_port_name
+  filter {
+    property = "/name"
+    operator = "="
+    value    = var.aside_secondary_port_name
   }
 }
 
@@ -22,8 +26,10 @@ data "equinix_fabric_service_profiles" "zside_sp" {
 
 data "equinix_fabric_ports" "zside_port" {
   count = var.zside_ap_type == "COLO" ? 1 : 0
-  filters {
-    name = var.zside_port_name
+  filter {
+    property = var.zside_port_name != "" ? "/name" : "/uuid"
+    operator = "="
+    value    = var.zside_port_name != "" ? var.zside_port_name : var.zside_port_uuid
   }
 }
 
@@ -246,3 +252,15 @@ resource "equinix_fabric_connection" "secondary_port_connection" {
     }
   }
 }
+
+check "port_name_uuid_mutual_exclusion" {
+  assert {
+    condition     = !(var.zside_port_name != "" && var.zside_port_uuid != "")
+    error_message = "ERROR: Cannot set both zside_port_name and zside_port_uuid. Please set only one."
+  }
+
+  assert {
+    condition     = !(var.aside_port_name != "" && var.aside_port_uuid != "")
+    error_message = "ERROR: Cannot set both aside_port_name and aside_port_uuid. Please set only one."
+  }
+}

modules/port-connection/variables.tf

@@ -47,6 +47,7 @@ variable "term_length" {
 variable "aside_port_name" {
   description = "Equinix A-Side Port Name; your tagging must match the encapsulation type of the port (DOT1Q or QINQ)"
   type        = string
+  default     = ""
 }
 variable "aside_secondary_port_name" {
   description = "Equinix A-Side Port Name; your tagging must match the encapsulation type of the port (DOT1Q or QINQ)"
@@ -156,3 +157,13 @@ variable "role" {
   type        = string
   default     = ""
 }
+variable "aside_port_uuid" {
+  description = "Equinix A-Side Port UUID; use this instead of aside_port_name. Only one of aside_port_name or aside_port_uuid can be set."
+  type        = string
+  default     = ""
+}
+variable "zside_port_uuid" {
+  description = "Equinix Z-Side Port UUID; use this instead of aside_port_name"
+  type        = string
+  default     = ""
+}