main.cpp

#include <Arduino.h>
#include <Preferences.h>

Preferences preferences;

static const uint32_t SERIAL_BAUD = 115200;
#ifdef RELEASE
static const char *NVS_NAMESPACE = "lumenlab";
#else
static const char *NVS_NAMESPACE = "lumenlab-dev";
#endif

String inputBuffer;

void processCommand(const String &cmd);
void writeKeyValue(const String &key, const String &value);
void getKeyValue(const String &key);
void dumpAll();
void clearAll();
void sendOK();
void sendError(const String &msg);
void printMenu();

void setup()
{
  Serial.begin(SERIAL_BAUD);
  preferences.begin(NVS_NAMESPACE, false);
  while (!Serial)
  {
    delay(10);
  }
  printMenu();
}

void loop()
{
  while (Serial.available())
  {
    char c = Serial.read();

    if (c == '\n')
    {
      inputBuffer.trim();
      if (inputBuffer.length() > 0)
      {
        processCommand(inputBuffer);
      }
      inputBuffer = "";
    }
    else
    {
      inputBuffer += c;
    }
  }
}

void processCommand(const String &cmd)
{
  if (cmd.startsWith("SET "))
  {
    int equalsIndex = cmd.indexOf('=');
    if (equalsIndex < 0)
    {
      sendError("INVALID_FORMAT");
      return;
    }

    String key = cmd.substring(4, equalsIndex);
    String value = cmd.substring(equalsIndex + 1);

    key.trim();
    value.trim();

    writeKeyValue(key, value);
  }
  else if (cmd.startsWith("GET "))
  {
    String key = cmd.substring(4);
    key.trim();
    getKeyValue(key);
  }
  else if (cmd == "GETALL")
  {
    dumpAll();
  }
  else if (cmd == "CLEAR")
  {
    clearAll();
  }
  else if (cmd == "REBOOT")
  {
    sendOK();
    delay(100);
    ESP.restart();
  }
  else if (cmd == "HELP")
  {
    printMenu();
  }
  else
  {
    sendError("UNKNOWN_COMMAND");
  }
}

void writeKeyValue(const String &key, const String &value)
{
  if (!preferences.begin(NVS_NAMESPACE, false))
  {
    sendError("NVS_BEGIN_FAILED");
    return;
  }

  size_t written = preferences.putString(key.c_str(), value);

  preferences.end();

  if (written > 0)
  {
    Serial.print("Wrote to NVS: ");
    Serial.print(key);
    Serial.print("=");
    Serial.println(value);
    sendOK();
  }
  else
    sendError("WRITE_FAILED");
}

void getKeyValue(const String &key)
{
  preferences.begin(NVS_NAMESPACE, true);
  String value = preferences.getString(key.c_str(), "__NOT_FOUND__");
  preferences.end();

  if (value == "__NOT_FOUND__")
  {
    sendError("NOT_FOUND");
    return;
  }

  Serial.print(key);
  Serial.print("=");
  Serial.println(value);
  sendOK();
}

void dumpAll()
{
  preferences.begin(NVS_NAMESPACE, true);

  size_t count = preferences.freeEntries();
  Serial.println("BEGIN_DUMP");

  const char *knownKeys[] = {
      "macAddress",
      "numLeds",
      "serialBaud",
      "boundary_1",
      "boundary_2",
      "boundary_3"};

  for (auto key : knownKeys)
  {
    if (!preferences.isKey(key))
    {
      Serial.print(key);
      Serial.println(" is not in memory.");
      continue;
    }

    String value = preferences.getString(key, "");
    if (value.length() > 0)
    {
      Serial.print(key);
      Serial.print("=");
      Serial.println(value);
    }
  }
  const char *knownHighScores[] = {
      "high_recall",
      "high_phase"};

  for (auto key : knownHighScores)
  {
    if (!preferences.isKey(key))
    {
      Serial.print(key);
      Serial.println(" is not in memory.");
      continue;
    }

    auto value = preferences.getString(key, "0");
    Serial.print(key);
    Serial.print("=");
    Serial.println(value);
  }

  preferences.end();

  Serial.println("END_DUMP");
  sendOK();
}

void clearAll()
{
  preferences.begin(NVS_NAMESPACE, false);
  bool result = preferences.clear();
  preferences.end();

  if (result)
    sendOK();
  else
    sendError("CLEAR_FAILED");
}

void sendOK()
{
  Serial.println("OK");
}

void sendError(const String &msg)
{
  Serial.print("ERROR:");
  Serial.println(msg);
}

void printMenu()
{
  Serial.println();
  Serial.println("=================================");
  Serial.println("LUMENLAB PROVISIONING MODE");
  char strBuff[64];
  snprintf(strBuff, sizeof(strBuff), "Namespace: %s", NVS_NAMESPACE);
  Serial.println(strBuff);
  Serial.println("Commands: SET, GET, GETALL, CLEAR, REBOOT, HELP");
  Serial.println("=================================");
  Serial.println("READY");
}