fingerprint-device-intelligence-android-demo/settings.gradle.kts at main · fingerprintjs/fingerprint-device-intelligence-android-demo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
@file:Suppress("UnstableApiUsage")

val localProperties = java.util.Properties().apply {
    val f = file("local.properties")
    if (f.exists()) f.inputStream().use { load(it) }
}

pluginManagement {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
    }
}
plugins {
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
}
dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
        mavenLocal {
            mavenContent {
                includeVersionByRegex("com.fingerprint.android", "pro", ".*")
            }
        }

        maven { url = uri("https://maven.fpregistry.io/releases") }

        maven {
            url = uri("https://maven.fpregistry.io/private-releases")
            // Reposilite Basic auth: username = token name, password = token secret
            credentials(PasswordCredentials::class) {
                username = providers.gradleProperty("privateMavenUser")
                    .orElse(providers.environmentVariable("PRIVATE_MAVEN_USER"))
                    .getOrElse(localProperties.getProperty("PRIVATE_MAVEN_USER", ""))
                password = providers.gradleProperty("privateMavenPassword")
                    .orElse(providers.environmentVariable("PRIVATE_MAVEN_REPO_TOKEN"))
                    .getOrElse(localProperties.getProperty("PRIVATE_MAVEN_REPO_TOKEN", ""))
            }
            content {
                includeGroup("com.fingerprint.android")
            }
        }
    }
}

rootProject.name = "Fingerprint Pro"
include(":app")