A tool that enables AI to execute Python code

[kerncos]

A tool that enables AI to execute Python code, replacing various other tools for tasks such as folder / file reading, modification, and deletion.

(defun gptel-execute-python-code (callback code)
    (let ((temp-file (make-temp-file "gptel-uv-" nil ".py"))
          (output-buffer (generate-new-buffer " *gptel-uv-output*")))
      (with-temp-file temp-file
	(insert code))
      (make-process
       :name "gptel-uv"
       :buffer output-buffer
       :command (list "uv" "run" temp-file)
       :connection-type 'pipe
       :sentinel
       (lambda (process _event)
	 (when (memq (process-status process) '(exit signal))
           (unwind-protect
               (let ((status (process-exit-status process))
                     (output (with-current-buffer (process-buffer process)
                               (buffer-string))))
		 (funcall callback
                          (if (= status 0)
                              output
                            (format "Error (exit %d): %s" status output))))
             (ignore-errors (delete-file temp-file))
             (kill-buffer (process-buffer process))))))))
   
(gptel-make-tool
	:name "execute_python_code"
	:function #'gptel-execute-python-code
	:description "Execute Python code in a transient, isolated environment using 'uv'. The code should be self-contained and output results to stdout. IMPORTANT: To use external libraries (e.g. pandas, requests), you MUST declare them using PEP 723 inline script metadata at the very top of your code.\n\nExample:\n# /// script\n# dependencies = [\"requests\"]\n# ///\n\nimport requests\n# ... rest of your code"
	:args '((:name "code"
			 :type string
			 :description "The complete Python source code to execute, including PEP 723 metadata if dependencies are needed."))
	:category "execute"
	:confirm t
	:async t)