Maintenance/settings.gradle.kts at main · kennytv/Maintenance · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")

dependencyResolutionManagement {
    repositories {
        maven("https://repo.papermc.io/repository/maven-public/")
        maven("https://repo.spongepowered.org/repository/maven-public/")
        maven("https://repo.codemc.io/repository/maven-public/")
        maven("https://repo.dmulloy2.net/repository/public/")
        maven("https://oss.sonatype.org/content/repositories/snapshots/")
        mavenCentral()
    }
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
}

pluginManagement {
    plugins {
        id("net.kyori.blossom") version "2.2.0"
        id("org.jetbrains.gradle.plugin.idea-ext") version "1.4"
        id("com.gradleup.shadow") version "9.3.1"
        id("dev.lukebemish.central-portal-publishing") version "0.1.7"
    }
}

rootProject.name = "maintenance-parent"

includeBuild("build-logic")

subproject("api")
subproject("api-proxy")
subproject("core")
subproject("core-proxy")
subproject("paper")
subproject("sponge")
subproject("bungee")
subproject("velocity")

fun subproject(name: String) {
    setupSubproject("maintenance-$name") {
        projectDir = file(name)
    }
}

inline fun setupSubproject(name: String, block: ProjectDescriptor.() -> Unit) {
    include(name)
    project(":$name").apply(block)
}