mumosa/CMakeLists.txt at master · libscran/mumosa · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
cmake_minimum_required(VERSION 3.24)

project(
    mumosa
    VERSION 0.3.0
    DESCRIPTION "Multi-modal analyses of single-cell data"
    LANGUAGES CXX
)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

# Library
add_library(mumosa INTERFACE)
add_library(libscran::mumosa ALIAS mumosa)

target_include_directories(mumosa INTERFACE
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/mumosa>)
target_compile_features(mumosa INTERFACE cxx_std_17)

# Dependencies
option(MUMOSA_FETCH_EXTERN "Automatically fetch mumosa's external dependencies." ON)
if(MUMOSA_FETCH_EXTERN)
    add_subdirectory(extern)
else()
    find_package(ltla_quickstats 0.2.0 CONFIG REQUIRED)
    find_package(knncolle_knncolle 3.1.0 CONFIG REQUIRED)
    find_package(ltla_sanisizer 0.2.0 CONFIG REQUIRED)
    find_package(libscran_scran_blocks 0.1.0 CONFIG REQUIRED)
endif()

target_link_libraries(mumosa INTERFACE knncolle::knncolle ltla::quickstats ltla::sanisizer libscran::scran_blocks)

# Tests
if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
    option(MUMOSA_TESTS "Build mumosa's test suite." ON)
else()
    option(MUMOSA_TESTS "Build mumosa's test suite." OFF)
endif()

if(MUMOSA_TESTS)
    include(CTest)
    if(BUILD_TESTING)
        add_subdirectory(tests)
    endif()
endif()

# Install
install(DIRECTORY include/
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mumosa)

install(TARGETS mumosa
    EXPORT mumosaTargets)

install(EXPORT mumosaTargets
    FILE libscran_mumosaTargets.cmake
    NAMESPACE libscran::
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/libscran_mumosa)

configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/Config.cmake.in
    "${CMAKE_CURRENT_BINARY_DIR}/libscran_mumosaConfig.cmake"
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/libscran_mumosa)

write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/libscran_mumosaConfigVersion.cmake"
    COMPATIBILITY SameMajorVersion)

install(FILES "${CMAKE_CURRENT_BINARY_DIR}/libscran_mumosaConfig.cmake"
    "${CMAKE_CURRENT_BINARY_DIR}/libscran_mumosaConfigVersion.cmake"
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/libscran_mumosa)