Action List implementation

[michaelfung]

I need to process many directives coming into a single endpoint. I use an action list inside a controller like below:
Is there room for improvement or better alternatives? Thanks.

# in a controller

my %action_list = (
    foo => sub($c, $p) {
      ...
    },
    bar => sub($c, $p) {
      ...
    },
    # ... and many more

    default => sub($c, $p) {
        $c->render(status => 400, text => 'invalid directive');
    }
);

sub parse($c) {
    my $m = $c->param('m') // 'default';
    my $p = $c->param('p') // 0;
    $m = 'default' unless defined $action_list{$m};
    $action_list{$m}->($c, $p);
}

[kiwiroy]

Can you render separate templates using action, or is there more going on in those subs? See link check example

Separate templates and methods

sub bar { return shift() ^ 2 }
sub foo { return shift() * -1 }

sub parse($c) {
  my $m      = $c->param('m') // 'default';
  my $p      = $c->param('p') // 0;
  my $method = {foo => \&foo, bar => \&bar}->{$m};

  return $c->render(action => $m, p => $method->($p)) if $method;
  return $c->render(action => 'default', status => 400);
}

foo.html.ep

foo with p value <%= $p %>

There's also shortcuts and placeholder types, but that might not fit with your route specification.

[michaelfung]

There are quite some processing in the subs. Output is not of concern(just success or failure). Thanks.

[jhthorsen]

I would go in the same direction, but with something like this:

sub parse ($c) {
  return $c->render(status => 400) unless my $action = $c->can(sprintf '_action_%s', $c->param('m') // 'default');
  return $c->render(p => $c->$action($c->param('p') // 0));
}

sub _action_bar { ... }
sub _action_foo { ... }

[michaelfung]

Wow, neat! Thanks!