[CMake] Fix #172: Add Boost as CMake external proj

Build Boost as CMake external project.  Boost is self-contained,
shipping its own configuration and build automation tooling
(`bootstap.sh` and `b2`).

WIP Boost

WIB boost

Author: ImmanuelHaffner

CMakeFiles/Boost.cmake

@@ -0,0 +1,52 @@
+set(Boost_LIBRARIES
+    system
+    container
+)
+list(TRANSFORM Boost_LIBRARIES PREPEND "Boost::" OUTPUT_VARIABLE BOOST_LINK_LIBRARIES)
+set(Boost_BYPRODUCTS)
+foreach(lib IN LISTS Boost_LIBRARIES)
+    list(APPEND Boost_BYPRODUCTS
+        "${CMAKE_BINARY_DIR}/third-party/src/Boost/stage/lib/${CMAKE_STATIC_LIBRARY_PREFIX}boost_${lib}${CMAKE_STATIC_LIBRARY_SUFFIX}"
+        "${CMAKE_BINARY_DIR}/third-party/src/Boost/stage/lib/${CMAKE_SHARED_LIBRARY_PREFIX}boost_${lib}${CMAKE_SHARED_LIBRARY_SUFFIX}"
+    )
+endforeach()
+
+if(is_release_build)
+    set(Boost_BUILD_TYPE release)
+else()
+    set(Boost_BUILD_TYPE debug)
+endif()
+ExternalProject_Add(
+    Boost
+    PREFIX third-party
+    URL https://github.com/boostorg/boost/releases/download/boost-1.84.0/boost-1.84.0.tar.xz
+    URL_MD5 893b5203b862eb9bbd08553e24ff146a
+    DOWNLOAD_EXTRACT_TIMESTAMP ON
+    CONFIGURE_COMMAND ./bootstrap.sh --with-toolset=clang --libdir="${CMAKE_BINARY_DIR}/third-party/src/Boost-build" --with-libraries=all
+    CONFIGURE_HANDLED_BY_BUILD true
+    BUILD_IN_SOURCE ON
+    BUILD_COMMAND ./b2 ${Boost_BUILD_TYPE}
+    BUILD_BYPRODUCTS ${Boost_BYPRODUCTS}
+    INSTALL_COMMAND ""
+)
+ExternalProject_Get_Property(Boost BINARY_DIR)
+set(BOOST_DIR ${BINARY_DIR})
+set(BOOST_LIBRARY_DIR "${BOOST_DIR}/stage/lib")
+
+include_directories(SYSTEM "${BOOST_DIR}")
+link_directories("${BOOST_LIBRARY_DIR}")
+
+set(BOOST_STATIC_LIBRARY_PATHS)
+set(BOOST_SHARED_LIBRARY_PATHS)
+foreach(lib IN LISTS Boost_LIBRARIES)
+    add_library("Boost::${lib}" ${LIB_TYPE} IMPORTED GLOBAL)
+    set(static_library_path "${BOOST_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}boost_${lib}${CMAKE_STATIC_LIBRARY_SUFFIX}")
+    set(shared_library_path "${BOOST_LIBRARY_DIR}/${CMAKE_SHARED_LIBRARY_PREFIX}boost_${lib}${CMAKE_SHARED_LIBRARY_SUFFIX}")
+    list(APPEND BOOST_STATIC_LIBRARY_PATHS "${static_library_path}")
+    list(APPEND BOOST_SHARED_LIBRARY_PATHS "${shared_library_path}")
+    if (BUILD_SHARED_LIBS)
+        set_target_properties("Boost::${lib}" PROPERTIES IMPORTED_LOCATION "${shared_library_path}")
+    else()
+        set_target_properties("Boost::${lib}" PROPERTIES IMPORTED_LOCATION "${static_library_path}")
+    endif()
+endforeach()

CMakeLists.txt

@@ -70,15 +70,6 @@ set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 set(THREADS_PREFER_PTHREAD_FLAG TRUE)
 find_package(Threads REQUIRED)
 
-# Boost
-if(${BUILD_SHARED_LIBS})
-    set(Boost_USE_STATIC_LIBS OFF)
-else()
-    set(Boost_USE_STATIC_LIBS ON)
-endif()
-set(Boost_USE_MULTITHREADED ON)
-find_package(Boost REQUIRED COMPONENTS system container)
-
 # Git
 find_package(Git REQUIRED)
 
@@ -221,6 +212,7 @@ set_source_files_properties(
 
 include("CMakeFiles/Catch2.cmake")
 include("CMakeFiles/Eigen.cmake")
+include("CMakeFiles/Boost.cmake")
 include("CMakeFiles/nlohmann_json.cmake")
 include("CMakeFiles/Replxx.cmake")
 include("CMakeFiles/Binaryen.cmake")

src/CMakeLists.txt

@@ -41,7 +41,7 @@ if(${WITH_V8})
 endif()
 
 # others
-target_link_libraries(${PROJECT_NAME} PUBLIC ${Boost_LIBRARIES} dl)
+target_link_libraries(${PROJECT_NAME} PUBLIC ${BOOST_LINK_LIBRARIES} dl)
 
 if(${BUILD_SHARED_LIBS})
     # When creating a SHARED library ${PROJECT_NAME} (libmutable.so), it will be stripped of unused and non-exported
@@ -74,10 +74,10 @@ else()
             "${PROJECT_BINARY_DIR}/third-party/src/V8-build/out/obj/${CMAKE_STATIC_LIBRARY_PREFIX}v8_monolith${CMAKE_STATIC_LIBRARY_SUFFIX}"
         )
     endif()
-    foreach(lib_target ${Boost_LIBRARIES})
-        get_target_property(lib_location ${lib_target} LOCATION)
-        list(APPEND static_libs ${lib_location})
+    foreach(lib_path IN LISTS BOOST_STATIC_LIBRARY_PATHS)
+        list(APPEND static_libs "${lib_path}")
     endforeach()
+    message(STATUS "Bundling libraries ${static_libs}")
 
     # Detect the toolchain to use for bundling.
     if (CMAKE_CXX_COMPILER_ID MATCHES "^(Clang)$")
@@ -173,19 +173,3 @@ set_target_properties(cardinality_gen PROPERTIES EXCLUDE_FROM_ALL ON)
 add_executable(query_slicer query_slicer.cpp)
 target_link_libraries(query_slicer ${PROJECT_NAME})
 set_target_properties(query_slicer PROPERTIES EXCLUDE_FROM_ALL ON)
-
-
-########################################################################################################################
-### Copy used system libraries to project, to be self-contained
-########################################################################################################################
-
-# Copy required Boost libraries
-if(${BUILD_SHARED_LIBS})
-    foreach(lib_target ${Boost_LIBRARIES})
-        get_target_property(lib_location ${lib_target} LOCATION)
-        add_custom_command(
-            TARGET ${PROJECT_NAME} POST_BUILD
-            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${lib_location} "${PROJECT_BINARY_DIR}/lib"
-        )
-    endforeach()
-endif()