|
| 1 | +open! Stdlib |
| 2 | +open Code |
| 3 | + |
| 4 | +(* |
| 5 | +ocamlc does not perform reference unboxing when emitting debugging |
| 6 | +information. Inlining can also enable additional reference unboxing. |
| 7 | +
|
| 8 | +We currently does not unbox references which are used within the scope |
| 9 | +of an exception handler. This should often not result in significant |
| 10 | +performance improvements, and is tricky to get right. Indeed, we would |
| 11 | +need to introduce variables for these references right before the |
| 12 | +[Pushtrap], and then add [Assign] instructions to keep their contents |
| 13 | +up to date whenever a reference is updated. |
| 14 | +*) |
| 15 | + |
| 16 | +let debug = Debug.find "unbox-refs" |
| 17 | + |
| 18 | +let times = Debug.find "times" |
| 19 | + |
| 20 | +let stats = Debug.find "stats" |
| 21 | + |
| 22 | +let rewrite refs block m = |
| 23 | + let m, l = |
| 24 | + List.fold_left |
| 25 | + ~f:(fun (m, acc) i -> |
| 26 | + match i with |
| 27 | + | Let (x, Block (0, [| y |], (NotArray | Unknown), Maybe_mutable)) |
| 28 | + when Var.Set.mem x refs -> Var.Map.add x y m, acc |
| 29 | + | Let (y, Field (x, 0, Non_float)) when Var.Map.mem x m -> |
| 30 | + (* Optimized away by Phisimpl *) |
| 31 | + m, Let (y, Prim (Extern "%identity", [ Pv (Var.Map.find x m) ])) :: acc |
| 32 | + | Offset_ref (x, n) when Var.Map.mem x m -> |
| 33 | + let y = Var.fresh () in |
| 34 | + ( Var.Map.add x y m |
| 35 | + , Let |
| 36 | + ( y |
| 37 | + , Prim |
| 38 | + ( Extern "%int_add" |
| 39 | + , [ Pv (Var.Map.find x m); Pc (Int (Targetint.of_int_exn n)) ] ) ) |
| 40 | + :: acc ) |
| 41 | + | Set_field (x, 0, Non_float, y) when Var.Map.mem x m -> Var.Map.add x y m, acc |
| 42 | + | Event _ -> ( |
| 43 | + match acc with |
| 44 | + | Event _ :: prev -> |
| 45 | + (* Avoid consecutive events (keep just the last one) *) |
| 46 | + m, i :: prev |
| 47 | + | _ -> m, acc) |
| 48 | + | _ -> m, i :: acc) |
| 49 | + block.body |
| 50 | + ~init:(m, []) |
| 51 | + in |
| 52 | + m, List.rev l |
| 53 | + |
| 54 | +let rewrite_cont relevant_vars vars (pc', args) = |
| 55 | + let refs, _ = Int.Hashtbl.find relevant_vars pc' in |
| 56 | + let vars = Var.Map.filter (fun x _ -> Var.Set.mem x refs) vars in |
| 57 | + pc', List.map ~f:snd (Var.Map.bindings vars) @ args |
| 58 | + |
| 59 | +let rewrite_function p variables pc = |
| 60 | + let relevant_vars = Int.Hashtbl.create 16 in |
| 61 | + let g = Structure.(dominator_tree (build_graph p.blocks pc)) in |
| 62 | + let rec traverse_tree g pc refs = |
| 63 | + let block = Addr.Map.find pc p.blocks in |
| 64 | + let refs' = |
| 65 | + List.fold_left |
| 66 | + ~f:(fun s i -> |
| 67 | + match i with |
| 68 | + | Let (x, Block (0, [| _ |], (NotArray | Unknown), Maybe_mutable)) |
| 69 | + when Var.Hashtbl.mem variables x -> Var.Set.add x s |
| 70 | + | _ -> s) |
| 71 | + ~init:refs |
| 72 | + block.body |
| 73 | + in |
| 74 | + Int.Hashtbl.add relevant_vars pc (refs, refs'); |
| 75 | + Addr.Set.iter (fun pc' -> traverse_tree g pc' refs') (Structure.get_edges g pc) |
| 76 | + in |
| 77 | + traverse_tree g pc Var.Set.empty; |
| 78 | + let rec traverse_tree' g pc blocks = |
| 79 | + let block = Addr.Map.find pc p.blocks in |
| 80 | + let refs, refs' = Int.Hashtbl.find relevant_vars pc in |
| 81 | + let vars = |
| 82 | + Var.Set.fold (fun x m -> Var.Map.add x (Var.fork x) m) refs Var.Map.empty |
| 83 | + in |
| 84 | + let params = List.map ~f:snd (Var.Map.bindings vars) @ block.params in |
| 85 | + let vars, body = rewrite refs' block vars in |
| 86 | + let branch = |
| 87 | + match block.branch with |
| 88 | + | Return _ | Raise _ | Stop -> block.branch |
| 89 | + | Branch cont -> Branch (rewrite_cont relevant_vars vars cont) |
| 90 | + | Cond (x, cont, cont') -> |
| 91 | + Cond |
| 92 | + ( x |
| 93 | + , rewrite_cont relevant_vars vars cont |
| 94 | + , rewrite_cont relevant_vars vars cont' ) |
| 95 | + | Switch (x, a) -> |
| 96 | + Switch (x, Array.map ~f:(fun cont -> rewrite_cont relevant_vars vars cont) a) |
| 97 | + | Pushtrap (cont, x, cont') -> |
| 98 | + Pushtrap |
| 99 | + ( rewrite_cont relevant_vars vars cont |
| 100 | + , x |
| 101 | + , rewrite_cont relevant_vars vars cont' ) |
| 102 | + | Poptrap cont -> Poptrap (rewrite_cont relevant_vars vars cont) |
| 103 | + in |
| 104 | + let blocks = Addr.Map.add pc { params; body; branch } blocks in |
| 105 | + Addr.Set.fold |
| 106 | + (fun pc' blocks -> traverse_tree' g pc' blocks) |
| 107 | + (Structure.get_edges g pc) |
| 108 | + blocks |
| 109 | + in |
| 110 | + let blocks = traverse_tree' g pc p.blocks in |
| 111 | + { p with blocks } |
| 112 | + |
| 113 | +let f p = |
| 114 | + let t = Timer.make () in |
| 115 | + let candidates = Var.Hashtbl.create 128 in |
| 116 | + let updated = Var.Hashtbl.create 128 in |
| 117 | + let visited = BitSet.create' p.free_pc in |
| 118 | + let discard x = Var.Hashtbl.remove candidates x in |
| 119 | + let check_field_access depth x = |
| 120 | + match Var.Hashtbl.find candidates x with |
| 121 | + | exception Not_found -> false |
| 122 | + | depth' -> |
| 123 | + if depth' = depth |
| 124 | + then true |
| 125 | + else ( |
| 126 | + Var.Hashtbl.remove candidates x; |
| 127 | + false) |
| 128 | + in |
| 129 | + (* A reference can be defined within the scope of an exception |
| 130 | + handler and used within the scope of another exception handler. |
| 131 | + So exception handlers should have strictly increasing depths |
| 132 | + within a function. [max_depth] is the largest depth used so far |
| 133 | + inside a function. This way, we know which depth to use when |
| 134 | + entering the scope of an exception handler. We use [depth_stack] |
| 135 | + to restore the previous depth when leaving the scope of an |
| 136 | + exception handler. *) |
| 137 | + let rec traverse depth_stack max_depth depth start_pc pc = |
| 138 | + if not (BitSet.mem visited pc) |
| 139 | + then ( |
| 140 | + BitSet.set visited pc; |
| 141 | + let block = Addr.Map.find pc p.blocks in |
| 142 | + List.iter |
| 143 | + ~f:(fun i -> |
| 144 | + match i with |
| 145 | + | Let (x, Block (0, [| _ |], (NotArray | Unknown), Maybe_mutable)) -> |
| 146 | + Freevars.iter_instr_free_vars discard i; |
| 147 | + Var.Hashtbl.replace candidates x depth |
| 148 | + | Let (_, Closure (_, (pc', _), _)) -> |
| 149 | + traverse [] (max_depth + 1) (max_depth + 1) pc' pc' |
| 150 | + | Let (_, Field (x, 0, Non_float)) -> ignore (check_field_access depth x) |
| 151 | + | Offset_ref (x, _) -> |
| 152 | + if check_field_access depth x then Var.Hashtbl.replace updated x start_pc |
| 153 | + | Set_field (x, _, Non_float, y) -> |
| 154 | + discard y; |
| 155 | + if check_field_access depth x then Var.Hashtbl.replace updated x start_pc |
| 156 | + | _ -> Freevars.iter_instr_free_vars discard i) |
| 157 | + block.body; |
| 158 | + Freevars.iter_last_free_var discard block.branch; |
| 159 | + match block.branch with |
| 160 | + | Pushtrap ((pc', _), _, (pc'', _)) -> |
| 161 | + traverse (depth :: depth_stack) (max_depth + 1) (max_depth + 1) start_pc pc'; |
| 162 | + traverse depth_stack max_depth depth start_pc pc'' |
| 163 | + | Poptrap (pc', _) -> |
| 164 | + traverse (List.tl depth_stack) max_depth (List.hd depth_stack) start_pc pc' |
| 165 | + | _ -> |
| 166 | + Code.fold_children |
| 167 | + p.blocks |
| 168 | + pc |
| 169 | + (fun pc' () -> traverse depth_stack max_depth depth start_pc pc') |
| 170 | + ()) |
| 171 | + in |
| 172 | + traverse [] 0 0 p.start p.start; |
| 173 | + if debug () |
| 174 | + then |
| 175 | + Print.program |
| 176 | + Format.err_formatter |
| 177 | + (fun _ i -> |
| 178 | + match i with |
| 179 | + | Instr (Let (x, _)) |
| 180 | + when Var.Hashtbl.mem candidates x && Var.Hashtbl.mem updated x -> "REF" |
| 181 | + | _ -> "") |
| 182 | + p; |
| 183 | + Var.Hashtbl.filter_map_inplace |
| 184 | + (fun x _depth -> try Some (Var.Hashtbl.find updated x) with Not_found -> None) |
| 185 | + candidates; |
| 186 | + let functions = |
| 187 | + Var.Hashtbl.fold (fun _ pc s -> Addr.Set.add pc s) candidates Addr.Set.empty |
| 188 | + in |
| 189 | + let p = Addr.Set.fold (fun pc p -> rewrite_function p candidates pc) functions p in |
| 190 | + if times () then Format.eprintf " reference unboxing: %a@." Timer.print t; |
| 191 | + if stats () |
| 192 | + then Format.eprintf "Stats - reference unboxing: %d@." (Var.Hashtbl.length candidates); |
| 193 | + p |
0 commit comments