leptos-rss/flake.nix at master · pati08/leptos-rss · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
{
  description = "Leptos SSR Project Build";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    crane.url = "github:ipetkov/crane";
  };

  outputs = { self, nixpkgs, rust-overlay, crane, ... }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ (import rust-overlay) ];
      };

      rustToolchain = pkgs.rust-bin.nightly.latest.default.override {
        extensions = [ "rust-src" "rust-analyzer" "rustfmt" "rustc-codegen-cranelift-preview" ];
        targets = [ "wasm32-unknown-unknown" "x86_64-unknown-linux-gnu" ];
      };
      craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
      tomlNameInfo = craneLib.crateNameFromCargoToml { cargoToml = ./Cargo.toml; };
      cargoPkgName = tomlNameInfo.pname;
      inherit (tomlNameInfo) version;

      server = targetPkgs: targetPkgs.callPackage ./nix/serverBuild.nix { inherit crane; };
      wasm = pkgs.callPackage ./nix/wasmBuild.nix { inherit crane; };
      # Build the site directory
      siteDerivation = pkgs.stdenv.mkDerivation {
        name = "${cargoPkgName}-site";
        src = self;

        buildInputs = with pkgs; [
          tailwindcss
          wasm-bindgen-cli
          binaryen
        ];

        configurePhase = ''
          mkdir -p $out/target/site/pkg
          cp -r ${./.}/public/* $out/target/site/
        '';

        buildPhase = ''
          # Build Tailwind CSS
          tailwindcss -i ./style/tailwind.css -o $out/target/site/pkg/${cargoPkgName}-${version}.css

          # Process WASM
          wasm-bindgen --target web --out-dir $out/target/site/pkg \
            --reference-types \
            ${wasm}/bin/${cargoPkgName}.wasm

          wasm-opt -Oz -o $out/target/site/pkg/${cargoPkgName}-${version}_bg.wasm \
            $out/target/site/pkg/${cargoPkgName}_bg.wasm

          mv $out/target/site/pkg/${cargoPkgName}.js $out/target/site/pkg/${cargoPkgName}-${version}.js
        '';
      };

      dockerImage = targetPkgs: targetPkgs.dockerTools.buildImage {
        name = cargoPkgName;
        tag = version;

        copyToRoot = [ (server targetPkgs) siteDerivation ];

        config = {
          Cmd = [ "${server targetPkgs}/bin/${cargoPkgName}" ];
          Env = [
            "LEPTOS_SITE_DIR=target/site"
            "LEPTOS_SITE_ADDR=0.0.0.0:3000"
            "LEPTOS_OUTPUT_NAME=${cargoPkgName}-${version}"
            "NIX_BUILD=1"
          ];
        };
      };

      crossPkgs = import nixpkgs {
        inherit system;
        overlays = [ (import rust-overlay) ];
        crossSystem.config = "aarch64-unknown-linux-gnu";
      };

    in {
      packages.${system} = {
        default = dockerImage pkgs;
        arm = dockerImage crossPkgs;
      };

      devShells.${system}.default = pkgs.mkShell {
        buildInputs = with pkgs; [
          rustToolchain
          tailwindcss
          wasm-bindgen-cli
          binaryen
          just
          irust
          leptosfmt
          mold
          dart-sass
          tailwindcss
          dive
          cargo-leptos
        ];
      };
    };
}