upload-github.gradle

apply from: '../artifactConfig.gradle'
apply plugin: 'maven-publish'

afterEvaluate {
    println "Project1: ${project.name}, artifactId from properties: '${project.artifactId}'"
    publishing {
        publications {
            maven(MavenPublication) {
                groupId = "$artifactConfig.group"
                artifactId = "$project.artifactId"

                if (artifactId == "android") {
                    from components.release

                    pom.withXml {
                        Node pomNode = asNode()
                        pomNode.dependencies.'*'.findAll() {
                            it.groupId.text() == artifactConfig.group
                        }.each() { it.parent().remove(it) }

                        pomNode.dependencies.'*'.findAll() {
                            it.scope.text() == 'runtime'
                        }.each { it.scope*.value = 'compile' }
                    }
                } else if (artifactId == "core") {
                    from components.java
                }
            }
        }
    }
}