LyraT crashing when Volume reaches 0.6

[pete-789]

This is a LyraT 4.3 board, the code is basically the hls-buffer-i2s.ino example modified to include a volume control controlled by an IR receiver. I get the stream okay through the speakers, and IR codes are received fine.

I'm starting the volume at 0.3 and incrementing (or decrementing) it by 0.1, min of 0, max of 1. The volume does increase (or decrease) but the board crashes and reboots when the volume reaches 0.6. It does this every time.

If I uncomment vcfg.allow_boost = true; and run the program the board crashes and reboots straight away.

I hope I have the code right:

// IR
#define DECODE_NEC   
#include "PinDefinitionsAndMore.h"
#include <IRremote.hpp> // include the library

// audio-tools
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecHelix.h"
#include "AudioTools/AudioCodecs/CodecMTS.h"
#include "AudioTools/Communication/HLSStream.h"
#include "AudioTools/Concurrency/RTOS.h"
#include "AudioTools/AudioLibs/AudioBoardStream.h"

float vol = 0.3;

// AudioBoardStream out(AudioKitEs8388V1);  // final output of decoded stream

AudioBoardStream out(LyratV43);  // final output of decoded stream
VolumeStream volume(out);

// I2SStream out;  // audio output

BufferRTOS<uint8_t> buffer(0);
QueueStream<uint8_t> queue(buffer);
HLSStream hls_stream("secret", "secret");  // audio data source
// decoder
MP3DecoderHelix mp3;
AACDecoderHelix aac;
MTSDecoder mts(aac);             // MPEG-TS (MTS) decoder
MultiDecoder multi(hls_stream);  // MultiDecoder using mime from hls_stream
// EncodedAudioOutput dec(&out, &multi); // changed for VolumeStream below
EncodedAudioOutput dec(&volume, &multi);

// 2 separate copy processes
StreamCopy copier_play(dec, queue);
StreamCopy copier_write_queue(queue, hls_stream);
Task writeTask("write", 1024 * 8, 10, 0);

// Arduino Setup
void setup(void) {
  Serial.begin(115200);

  IrReceiver.begin(12, DISABLE_LED_FEEDBACK);    

  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Warning);

  // get the board config
  auto config = out.defaultConfig(TX_MODE);

  // set initial volume
  auto vcfg = volume.defaultConfig();
  vcfg.copyFrom(config);
  // vcfg.allow_boost = true; // activate amplification using linear control
  volume.begin(vcfg); // we need to provide the bits_per_sample and channels
  volume.setVolume(vol);  

  // https://streams.radiomast.io/ref-128k-mp3-stereo/hls.m3u8
  // https://streams.radiomast.io/ref-128k-aaclc-stereo/hls.m3u8
  // https://streams.radiomast.io/ref-64k-heaacv1-stereo/hls.m3u8
  if (!hls_stream.begin(
          "https://streams.radiomast.io/ref-128k-mp3-stereo/hls.m3u8"))
    stop();

  // register decoders with mime types
  multi.addDecoder(mp3, "audio/mpeg");
  multi.addDecoder(aac, "audio/aac");
  multi.addDecoder(mts, "video/MP2T");  // MPEG-TS

  // start output
  auto cfg = out.defaultConfig(TX_MODE);
  // add optional configuration here: e.g. pins
  out.begin(cfg);

  buffer.resize(10 * 1024);  // increase to 50k psram
  dec.begin();               // start decoder
  queue.begin(100);          // activate read when 100% full

  writeTask.begin([]() { copier_write_queue.copy(); });
}



void loop() { 
  
  copier_play.copy(); 

  if (IrReceiver.decode()) {

      if (IrReceiver.decodedIRData.flags & IRDATA_FLAGS_IS_REPEAT) {
        IrReceiver.resume();
      } else {
        switch (IrReceiver.decodedIRData.command) {
            case 0x7:
              Serial.println(F("Vol-"));
              if (vol > 0) {
                vol -= 0.1;
                Serial.println(vol);
                volume.setVolume(vol); 
              }
              break;
            case 0x15:
              Serial.println(F("Vol+"));
              if (vol < 1) { // 0.5
                vol += 0.1;
                Serial.println(vol);                
                volume.setVolume(vol);
              }
              break;
        }
        
        IrReceiver.resume();

      }
  }

}

Any ideas and/or guidance much appreciated.

I've had trouble getting log information, as recommended I've been running it at Warning, and there is an awful lot of output at Info level.

If I set AudioToolsLogLevel::Info the sound breaks up but I can raise the Volume further (to a point).

Boot with AudioToolsLogLevel::Info
Vol+
0.70
[I] VolumeStream.h : 201 - setVolume: 0.700000 at 0
[I] VolumeStream.h : 201 - setVolume: 0.700000 at 1
Vol+
0.80
[I] VolumeStream.h : 201 - setVolume: 0.800000 at 0
[I] VolumeStream.h : 201 - setVolume: 0.800000 at 1
Vol+
0.90
[I] VolumeStream.h : 201 - setVolume: 0.900000 at 0
[I] VolumeStream.h : 201 - setVolume: 0.900000 at 1
Vol+
1.00
[E] VolumeStream.h : 194 - Invalid volume: 1.000000
[E] VolumeStream.h : 194 - Invalid volume: 1.000000

[pschatzmann]

A couple of hints:

• Log your available RAM: Wifi and codecs use a lot of RAM and you might just run out of available RAM
• Analyze the backtrace that should show you what line of code is causing the issue

Try to remove the Task writeTask("write", 1024 * 8, 10, 0); to double check that this is not your source of trouble...

[pete-789]

Ah, thanks... I have no idea how to do either of those things, so a-googling I go!

[pete-789]

Actually it is not just Volume but after a number of any keys that I'm translating pressed on the IR remote control.

RAM seems fine, and there is no backtrace - the board just reboots. I think this might just be the strange character and usage of Pin 12.

So... I'm trying Pin 13 (with DIP switch 4 ON this maps to the JTAG header MTCK). As per the Espressif Hardware Ref, this pin is used for

JTAG MTCK, MicroSD D3 and Audio Vol- (TP)

I can switch off the SD integration with sd_active = false; - thanks for the tip!

Is it possible to switch off button integration? Presumably you have the Audio Vol- (TP) button already mapped to Pin 13 on the LyraT 4.3, which could be why I'm getting

E (4216) gpio: gpio_pullup_en(78): GPIO number error (input-only pad has no internal PU)
E (4217) gpio: gpio_pullup_en(78): GPIO number error (input-only pad has no internal PU)
Warning: Pin '13' not set up because of conflict

(I can use the IR receiver fine on Pin 13 in a simple program).

[pschatzmann]

Did you try if you can reproduce the issue w/o using tasks ?

[pete-789]

Thanks for the reply Phil.

I hope this is what you meant, I slowly added in lines of code until the error happened, it is the line

out.begin(config); // <<<<<<

the error is

E (4213) gpio: gpio_pullup_en(78): GPIO number error (input-only pad has no internal PU)
E (4214) gpio: gpio_pullup_en(78): GPIO number error (input-only pad has no internal PU)

here is code

// IR
#define IR_RECEIVE_PIN 13  // DIP switch 4 ON
#include <TinyIRReceiver.hpp>

// audio-tools
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecHelix.h"
#include "AudioTools/AudioCodecs/CodecMTS.h"
#include "AudioTools/Communication/HLSStream.h"
#include "AudioTools/Concurrency/RTOS.h"
#include "AudioTools/AudioLibs/AudioBoardStream.h"

float vol = 0.3;

AudioBoardStream out(LyratV43);
VolumeStream volume(out);
BufferRTOS<uint8_t> buffer(0);
QueueStream<uint8_t> queue(buffer);
HLSStream hls_stream("secret", "secret");

MP3DecoderHelix mp3;
AACDecoderHelix aac;
MTSDecoder mts(aac);             // MPEG-TS (MTS) decoder
MultiDecoder multi(hls_stream);  // MultiDecoder using mime from hls_stream
EncodedAudioOutput dec(&volume, &multi);

StreamCopy copier_play(dec, queue);
StreamCopy copier_write_queue(queue, hls_stream);
Task writeTask("write", 1024 * 8, 10, 0);

void setup(void) {
  Serial.begin(115200);

  initPCIInterruptForTinyReceiver(); // Enables the interrupt generation on change of IR input signal

  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Warning);

  // get and set the board config
  auto config = out.defaultConfig(TX_MODE);
  config.sd_active = false;  // added

  // set initial volume
  auto vcfg = volume.defaultConfig();
  vcfg.copyFrom(config);
  volume.begin(vcfg); // we need to provide the bits_per_sample and channels
  volume.setVolume(vol);  

  if (!hls_stream.begin(
          "https://streams.radiomast.io/ref-128k-mp3-stereo/hls.m3u8"))
    stop();

  // register decoders with mime types
  multi.addDecoder(mp3, "audio/mpeg");
  multi.addDecoder(aac, "audio/aac");
  multi.addDecoder(mts, "video/MP2T");  // MPEG-TS

  // start output
  out.begin(config); // <<<<<<


}

void loop() { 

  
}

[pschatzmann]

I am getting these errors as well: this has no impact and can be ignored...
AudioBoardStream has automatic key support, I2SCodecStream has not key support.

[pete-789]

Ah, many thanks, I2SCodecStream might be what I need then.

[pete-789]

Unfortunately using I2SCodecStream doesn't make any difference - pin 13 still won't work.

To recap, on the LyraT 4.3 board, with DIP switch 4 ON (Pin 13 maps to the MTCK JTAG header pin) I can use Pin 13 successfully to blink an LED or read from the IR Receiver (without your code).

(When I was trying to use Pin 12 along with your code the IR Receiver worked - before it reset the board. So the IR Receiver code is okay).

I have sd_active = false; set as you recommended. There must be something still using (or blocking) Pin 13 though?

I see Pin 13 (on the LyraT 4.3) in DriverPIns.h:

/**
 * @brief Pins for Lyrat 4.3 - use the PinsLyrat43 object!
 * @author Phil Schatzmann
 * @copyright GPLv3
 */
class PinsLyrat43Class : public DriverTouchClass {
 public:
  PinsLyrat43Class() {
    // sd pins
    addSPI(ESP32PinsSD);
    // add i2c codec pins: scl, sda, port, frequency
    addI2C(PinFunction::CODEC, 23, 18);
    // add i2s pins: mclk, bck, ws,data_out, data_in ,(port)
    addI2S(PinFunction::CODEC, 0, 5, 25, 26, 35);

    // add other pins
    addPin(PinFunction::KEY, 36, PinLogic::InputActiveLow, 1);
    addPin(PinFunction::KEY, 39, PinLogic::InputActiveLow, 2);
    addPin(PinFunction::KEY, 33, PinLogic::InputActiveLow, 3);
    addPin(PinFunction::KEY, 32, PinLogic::InputActiveLow, 4);
    addPin(PinFunction::KEY, 13, PinLogic::InputActiveLow, 5); 
    addPin(PinFunction::KEY, 27, PinLogic::InputActiveLow, 6);
    addPin(PinFunction::AUXIN_DETECT, 12, PinLogic::InputActiveLow);
    addPin(PinFunction::HEADPHONE_DETECT, 19, PinLogic::InputActiveLow);
    addPin(PinFunction::PA, 21, PinLogic::Output);
    addPin(PinFunction::LED, 22, PinLogic::Output);
  }
};

and Pin 13 is also referenced in ESP32PinsSD (as per addSPI(ESP32PinsSD);)

Could either of these be causing the problem?

Is there a way to see whether Pin 13 is still being used in your code (and by what)?

Sorry to keep on about this but the LyraT board offers very little in the way of 'user' pins, it would be great if at least one could be used with your code!

[pschatzmann]

I think it does not really matter as long as you don't use the sd drive or the key 5.
After calling out.begin() you can call your own pinMode() call and do whatever you wish, just be aware that pressing key 5 will interfere with your ir processing...

[pete-789]

Thanks for the reply Phil.

Moving the IR Receiver setup call to after out.begin() made Pin 13 work!

Oddly, the board resets if the Volume is more than 0.7... This happens whether I hard code the value, or use the IR Receiver handset +/-. So maxVolume will be coded as 0.7

The other buttons on the handset seem to be fine (they weren't using Pin 12).

Once again, many thanks for your help - and your patience !