build.gradle

plugins {
	id "io.github.gradle-nexus.publish-plugin" version "2.0.0"
	id "signing"
	id 'java-gradle-plugin'
	id "groovy"
	id "eclipse"
	id "maven-publish"
	id "com.gradle.plugin-publish" version "2.1.1"
	id 'to.wetransform.semantic-release-version' version '2.1.3'
	id 'to.wetransform.conventions' version '3.0.0'
}

wetransform {
	setup {
		spotless  {
			licenseHeader = '''\
				/*
				 * Copyright $YEAR the original author or authors.
				 *
				 * Licensed under the Apache License, Version 2.0 (the "License");
				 * you may not use this file except in compliance with the License.
				 * You may obtain a copy of the License at
				 *
				 *      http://www.apache.org/licenses/LICENSE-2.0
				 *
				 * Unless required by applicable law or agreed to in writing, software
				 * distributed under the License is distributed on an "AS IS" BASIS,
				 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
				 * See the License for the specific language governing permissions and
				 * limitations under the License.
				 */
				'''.stripIndent()
		}

		publish {
			// publishing is configured manually below, not using conventions here
			disable = true
		}
	}
}

repositories {
	mavenCentral()
}

group = 'org.standardout'

jar {
	// include license into jar
	into 'META-INF', {
		from 'LICENSE'
	}
}

def isCI = "true".equals(System.getenv("CI"))
def isRelease = !version.endsWith('-SNAPSHOT')

dependencies {
	implementation gradleApi()
	implementation libs.bnd.bndlib
	implementation libs.osgi.core
	implementation libs.commons.io
	implementation libs.gradle.download.task
	implementation localGroovy()

	// Testing
	testImplementation testLibs.junit.jupiter
	testRuntimeOnly testLibs.junit.platform.launcher

	testImplementation testLibs.assertj.core
}

test {
	useJUnitPlatform()
}

tasks.wrapper {
	distributionType = Wrapper.DistributionType.ALL
	gradleVersion = '9.4.1'
}

sourceSets {
	functionalTest {
		groovy.srcDir file('src/functionalTest/groovy')
		resources.srcDir file('src/functionalTest/resources')
		compileClasspath += sourceSets.main.output + configurations.testCompileClasspath
		runtimeClasspath += output + compileClasspath + configurations.testRuntimeClasspath
	}
}

tasks.register('functionalTest', Test) {
	description = 'Runs the functional tests.'
	group = 'verification'
	testClassesDirs = sourceSets.functionalTest.output.classesDirs
	classpath = sourceSets.functionalTest.runtimeClasspath
	useJUnitPlatform()
	maxParallelForks = 1
}

tasks.named('check') {
	dependsOn tasks.named('functionalTest')
}

dependencies {
	functionalTestImplementation testLibs.junit.jupiter
	functionalTestRuntimeOnly testLibs.junit.platform.launcher
	functionalTestImplementation testLibs.assertj.core
	functionalTestImplementation gradleTestKit()
}

gradlePlugin {
	testSourceSets.add(sourceSets.functionalTest)
	def githubUrl = 'https://github.com/stempler/bnd-platform'
	website = githubUrl
	vcsUrl = githubUrl
	plugins {
		bndPlatform {
			id = 'org.standardout.bnd-platform'
			implementationClass = 'org.standardout.gradle.plugin.platform.PlatformPlugin'
			displayName = 'bnd-platform'
			description = 'Build OSGi bundles and p2 repositories / Eclipse Update Sites from existing libraries and their dependencies, e.g. from Maven repositories. Useful for instance for creating a target platform for Eclipse/Equinox or Maven Tycho build from third party dependencies.'
			tags.set([
				'bnd',
				'osgi',
				'p2',
				'eclipse',
				'tycho'
			])
		}
	}
}

nexusPublishing {
	repositories {
		// see https://central.sonatype.org/publish/publish-portal-ossrh-staging-api/#configuration
		sonatype {
			nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
			snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
		}
	}
}

def configurePom(pom) {
	pom.description = 'Build OSGi bundles and Eclipse Update Sites from existing JARs, e.g. from Maven repositories (Plugin for Gradle)'
	pom.url = 'https://github.com/stempler/bnd-platform'

	pom.scm {
		url = 'scm:git:https://github.com/stempler/bnd-platform.git'
		connection = 'scm:git:https://github.com/stempler/bnd-platform.git'
		developerConnection = 'scm:git:https://github.com/stempler/bnd-platform.git'
	}

	pom.licenses {
		license {
			name = 'The Apache Software License, Version 2.0'
			url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
			distribution = 'repo'
		}
	}

	pom.developers {
		developer {
			id = 'stempler'
			name = 'Simon Templer'
			email = 'simon@templer.cc'
		}
	}
}

publishing {
	publications {
		pluginMaven(MavenPublication) {
			groupId "${group}"
			artifactId 'bnd-platform'
			version "${version}"

			pom {
				name = 'bnd-platform'
				packaging = 'jar'

				configurePom(pom)
			}
		}
	}

	afterEvaluate {
		publications {
			bndPlatformPluginMarkerMaven {
				pom { pom ->
					configurePom(pom)
				}
			}
		}
	}
}

// sign all artifacts
signing {
	if (isCI) {
		// use in ASCII armored key for CI
		def signingKey = findProperty("signingKey")
		def signingPassword = findProperty("signingPassword")
		useInMemoryPgpKeys(signingKey, signingPassword)
	}
}

tasks.withType(Sign) {
	onlyIf {
		isRelease || isCI
	}
}