kaig/Justfile at main · surrealdb/kaig · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
mod demo-graph './examples/demo-graph'
mod demo-ingest-throttled './examples/demo-ingest-throttled'

# -- Variables

db_version := "v3.0.4"

default:
    @just --list

format:
    uv run ruff check --fix --select I
    uv run ruff format

lint:
    -time uv run ruff check
    -time uv run basedpyright src/
    -time uv run basedpyright -p examples/demo-graph
    -time uv run basedpyright -p examples/demo-simple
    -time uv run basedpyright -p examples/knowledge-graph
    # -time uv run ty check

# DB for knowledge-graph example
knowledge-graph-db:
    docker run --rm --pull always -p 8000:8000 -v ./databases:/databases surrealdb/surrealdb:{{ db_version }} start -u root -p root rocksdb:databases/knowledge-graph-v3

# Run knowledge-graph example agent chat UI
knowledge-graph-agent DB:
    DB_NAME={{ DB }} uv run --env-file .env uvicorn knowledge_graph.agent:app --host 127.0.0.1 --port 7932

# Alias for knowledge-graph-db
kg-db:
    @just knowledge-graph-db

# Alias for knowledge-graph
kg DB:
    @just knowledge-graph {{ DB }}

# Alias for knowledge-graph-agent
kg-agent DB:
    @just knowledge-graph-agent {{ DB }}

# Build kaig-app (SvelteKit SSR)
kaig-app-build:
    bun install --cwd kaig-app
    bun run --cwd kaig-app build

# Dev server for kaig-app
kaig-app-dev:
    bun run --cwd kaig-app dev

# Preview production build
kaig-app-preview:
    bun run --cwd kaig-app preview

kaig-app-format:
    bun run --cwd kaig-app format

# Run SurrealDB migrations for kaig-app
kaig-app-migrate:
    bun run kaig-app/scripts/migrate.ts

# Run kaig-app worker
kaig-app-worker:
    uv run --env-file .env examples/knowledge-graph/src/knowledge_graph/ingest.py

# Local SurrealDB for kaig-app
kaig-app-db:
    docker run --rm --pull always -p 8000:8000 surrealdb/surrealdb:{{ db_version }} start -u root -p root