[Bug]: False positive return-check error when using match case accessing a JSON field

[mahimadesilva]

Description

When using a match expression on a JSON field inside a do { } on fail block, and each match case performs a return, the Ballerina compiler reports:

ERROR [main.bal:(134:1,134:2)] this function must return a result

This issue occurs even when a wildcard (_) case is included.

Steps to Reproduce

Reproducible Code:

public function doEval(json selectExpression) returns string|error {
    do {
        match selectExpression.key1 {
            "column" =>
            {
                return "c";
            }
            "select" =>
            {
                return "s";
            }
            _ =>
            {
                return "d";
            }

        }
    } on fail error err {
        return err;
    }
}

Affected Version(s)

Ballerina 2201.12.10 (Swan Lake Update 12)

OS, DB, other environment details and versions

Windows 10

Related area

-> Compilation

Related issue(s) (optional)

No response

Suggested label(s) (optional)

No response

Suggested assignee(s) (optional)

No response

[senuriwick]

After investigating the compiler internals, this is actually expected behavior, not a bug.

selectExpression.key1 is a lax field access on a json value, which always produces type json|error. The error case represents a failed field access at runtime. The _ wildcard in Ballerina only covers values whose basic type is not error, so the error portion of json|error is left unhandled, and the compiler correctly reports that the function may not return.

To fix this, you have two options:

Option 1 - use check to propagate the error before matching:

public function doEval(json selectExpression) returns string|error {
    match check selectExpression.key1 {
        "column" => { return "c"; }
        "select" => { return "s"; }
        _ => { return "d"; }
    }
}

Option 2 - explicitly handle the error in the match:

public function doEval(json selectExpression) returns string|error {
    match selectExpression.key1 {
        "column" => { return "c"; }
        "select" => { return "s"; }
        error (var _) => { return "e"; }
        _ => { return "d"; }
    }
}

The do/on fail wrapper is not relevant to this diagnostic. The same error occurs without it. The root cause is that _ does not cover error values.