chore: Migrate Build System to Kotlin DSL and Fix Lint Issues

README.md

@@ -28,9 +28,9 @@ It enables you to write more concise, idiomatic Kotlin.
 
 If you are using the Places SDK through Google Play Services:
 
-```groovy
+```kotlin
 dependencies {
-    implementation 'com.google.maps.android:places-ktx:3.6.0' // {x-release-please-version}
+    implementation("com.google.maps.android:places-ktx:3.6.0") // {x-release-please-version}
 }
 ```
 

app/build.gradle.kts

@@ -0,0 +1,102 @@
+/*
+ * Copyright 2024 Google Inc.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+plugins {
+    alias(libs.plugins.androidApplication)
+    alias(libs.plugins.kotlinAndroid)
+    alias(libs.plugins.kotlinKapt)
+    alias(libs.plugins.hilt)
+    alias(libs.plugins.secrets)
+    alias(libs.plugins.compose)
+}
+
+android {
+    lint {
+        sarifOutput = layout.buildDirectory.file("reports/lint-results.sarif").get().asFile
+    }
+
+    compileSdk = libs.versions.androidCompileSdk.get().toInt()
+
+    defaultConfig {
+        applicationId = "com.google.maps.android.ktx.demo"
+        minSdk = libs.versions.androidMinSdk.get().toInt()
+        targetSdk = libs.versions.androidTargetSdk.get().toInt()
+        versionCode = 1
+        versionName = "1.0"
+        multiDexEnabled = true
+    }
+
+    buildFeatures {
+        buildConfig = true
+        compose = true
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = false
+            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
+        }
+    }
+
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_17
+        targetCompatibility = JavaVersion.VERSION_17
+    }
+
+    namespace = "com.google.places.android.ktx.demo"
+}
+
+kotlin {
+    compilerOptions {
+        jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_17)
+        freeCompilerArgs.add("-Xopt-in=kotlin.RequiresOptIn")
+    }
+}
+
+dependencies {
+    implementation(platform(libs.androidx.compose.bom))
+
+    // Core Compose libraries
+    implementation(libs.androidx.compose.ui)
+    implementation(libs.androidx.compose.ui.tooling.preview)
+    implementation(libs.androidx.compose.material3)
+    implementation(libs.androidx.activity.compose)
+
+    debugImplementation(libs.androidx.compose.ui.tooling)
+    debugImplementation(libs.androidx.compose.ui.test.manifest)
+
+    implementation(libs.appcompat)
+    implementation(libs.core.ktx)
+    implementation(libs.kotlin.stdlib)
+    implementation(libs.multidex)
+    implementation(libs.play.services.maps)
+    implementation(libs.fragment.ktx)
+    implementation(libs.lifecycle.runtime.ktx)
+    implementation(libs.material)
+    implementation(libs.volley)
+
+    // Hilt
+    implementation(libs.hilt.android)
+    implementation(libs.runtime)
+    kapt(libs.hilt.android.compiler)
+
+    implementation(project(":places-ktx"))
+}
+
+secrets {
+    propertiesFileName = "secrets.properties"
+    defaultPropertiesFileName = "local.defaults.properties"
+}