Add initial support for build system generation with CMake

CMakeLists.txt

@@ -0,0 +1,190 @@
+cmake_minimum_required(VERSION 3.28...4.0)
+
+project(pjproject
+  VERSION 2.15
+  DESCRIPTION "Multimedia communication library"
+  HOMEPAGE_URL "http://www.pjsip.org"
+  LANGUAGES C CXX
+)
+
+# project modules
+list(INSERT CMAKE_MODULE_PATH 0 "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
+
+# experimental warning notice
+option(PJ_SKIP_EXPERIMENTAL_NOTICE OFF)
+if (NOT PJ_SKIP_EXPERIMENTAL_NOTICE)
+  message(WARNING
+    " ****************************************************\n"
+    " * Building `pjproject` with CMake is experimental  *\n"
+    " *--------------------------------------------------*\n"
+    " * Tested platforms:                                *\n"
+    " * - Linux x86_64                                   *\n"
+    " ****************************************************\n"
+    "Set `PJ_SKIP_EXPERIMENTAL_NOTICE=ON` to disable this warning"
+  )
+endif()
+
+# ##############################################################################
+# Testing support
+
+if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
+  include(CTest)
+endif()
+
+if(BUILD_TESTING)
+  if(CMAKE_SYSTEM_NAME MATCHES "rtems")
+    set(PJ_TEST_MAIN "main_rtems.c")
+  else()
+    set(PJ_TEST_MAIN "main.c")
+  endif()
+endif()
+
+# ##############################################################################
+# Installation preparation
+
+include(GNUInstallDirs)
+
+# add `$ORIGIN` to targets' RPATH
+if(BUILD_SHARED_LIBS)
+  if(APPLE)
+    list(APPEND CMAKE_INSTALL_RPATH
+      "@loader_path"
+      "@executable_path/../${CMAKE_INSTALL_LIBDIR}"
+    )
+  elseif(UNIX)
+    list(APPEND CMAKE_INSTALL_RPATH
+      "$ORIGIN"
+      "$ORIGIN/../${CMAKE_INSTALL_LIBDIR}"
+    )
+  endif()
+endif()
+
+# ##############################################################################
+# Sub-directories
+
+# base library
+add_subdirectory(pjlib)
+
+# third-party libraries
+add_subdirectory(third_party)
+
+# remaning libraries
+add_subdirectory(pjlib-util)
+add_subdirectory(pjnath)
+add_subdirectory(pjmedia)
+add_subdirectory(pjsip)
+add_subdirectory(pjsip-apps)
+
+# ##############################################################################
+# Installation
+
+set(install_targets
+  pjlib
+  pjlib-ssl
+  pjlib++
+  pjlib-util
+  pjnath
+  pjmedia
+  pjmedia-codec
+  pjmedia-audiodev
+  pjmedia-videodev
+  pjsip
+  pjsip-simple
+  pjsip-ua
+  pjsua-lib
+  pjsua2
+  pjsua
+)
+
+# set `VERSION` and `SO_VERSION`
+foreach(target IN LISTS install_targets)
+  set_target_properties(${target} PROPERTIES
+    VERSION ${PROJECT_VERSION}
+    SOVERSION ${PROJECT_VERSION_MAJOR}
+  )
+endforeach()
+
+# install targets
+install(
+  TARGETS ${install_targets}
+  EXPORT PjTargets
+
+  FILE_SET HEADERS
+    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
+    COMPONENT PjDevelopment
+  FILE_SET config_headers
+    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
+    COMPONENT PjDevelopment
+  RUNTIME
+    DESTINATION "${CMAKE_INSTALL_BINDIR}"
+    COMPONENT PjRuntime
+  LIBRARY
+    DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+    COMPONENT PjRuntime
+    NAMELINK_COMPONENT PjDevelopment
+  ARCHIVE
+    DESTINATION  "${CMAKE_INSTALL_BINDIR}"
+    COMPONENT PjDevelopment
+)
+
+# ##############################################################################
+# CMAKe Package config
+
+include(CMakePackageConfigHelpers)
+
+set(PJ_CMAKE_INSTALL_DIR         "${CMAKE_INSTALL_LIBDIR}/cmake/Pj")
+set(PJ_CMAKE_TARGETS_FILE        "PjTargets.cmake")
+set(PJ_CMAKE_CONFIG_FILE         "PjConfig.cmake")
+set(PJ_CMAKE_CONFIG_VERSION_FILE "jConfigVersion.cmake")
+
+# install exports
+install(
+  EXPORT      PjTargets
+  NAMESPACE   Pj::
+  FILE        "${PJ_CMAKE_TARGETS_FILE}"
+  DESTINATION "${PJ_CMAKE_INSTALL_DIR}"
+  COMPONENT   PjDevelopment
+)
+
+# write package config
+configure_package_config_file(
+  "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Pj/${PJ_CMAKE_CONFIG_FILE}.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/${PJ_CMAKE_CONFIG_FILE}"
+
+  INSTALL_DESTINATION "${PJ_CMAKE_INSTALL_DIR}"
+)
+
+# write package config version
+write_basic_package_version_file(
+  "${PJ_CMAKE_CONFIG_VERSION_FILE}"
+
+  COMPATIBILITY SameMajorVersion
+)
+
+install(FILES
+  "${CMAKE_CURRENT_BINARY_DIR}/${PJ_CMAKE_CONFIG_FILE}"
+  "${CMAKE_CURRENT_BINARY_DIR}/${PJ_CMAKE_CONFIG_VERSION_FILE}"
+
+  DESTINATION "${PJ_CMAKE_INSTALL_DIR}"
+  COMPONENT PjDevelopment
+)
+
+# ##############################################################################
+# pkg-config file
+
+set(PREFIX "${CMAKE_INSTALL_PREFIX}") # this should be done at install time
+set(LIBDIR "${PREFIX}/${CMAKE_INSTALL_LIBDIR}")
+set(INCLUDEDIR "${PREFIX}/${CMAKE_INSTALL_INCLUDEDIR}")
+set(PJ_VERSION "${PROJECT_VERSION}")
+set(PJ_INSTALL_LDFLAGS "")
+set(PJ_INSTALL_LDFLAGS "")
+
+configure_file(
+  "${CMAKE_CURRENT_SOURCE_DIR}/libpjproject.pc.in"
+  "${CMAKE_CURRENT_BINARY_DIR}/libpjproject.pc"
+)
+
+install(
+  FILES "${CMAKE_CURRENT_BINARY_DIR}/libpjproject.pc"
+  DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig"
+)

cmake/DetectWebRTCParameters.cmake

@@ -0,0 +1,36 @@
+include(Pj/DetectArch)
+pj_detect_arch(arch)
+pj_detect_arch_simd_ext(simd_inst simd_flags)
+
+set(WEBRTC_ARCH "${arch}")
+set(WEBRTC_ARCH_SIMD "${simd_inst}")
+set(WEBRTC_COMPILE_OPTIONS ${simd_flags})
+set(WEBRTC_COMPILE_DEFINITIONS WEBRTC_APM_DEBUG_DUMP=0)
+
+# operating system definitions
+if(IOS)
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_IOS=1 WEBRTC_POSIX=1)
+elseif(DARWIN)
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_MAC=1 WEBRTC_POSIX=1)
+elseif(ANDROID)
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_ANDROID=1 WEBRTC_POSIX=1)
+elseif(LINUX)
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_LINUX=1 WEBRTC_POSIX=1)
+elseif(WIN32)
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_WIN=1)
+endif()
+
+if (MSVC)
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS NOMINMAX)
+endif()
+
+# architecture definitions
+if(arch STREQUAL "arm64")
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_ARCH_ARM64=1)
+elseif(arch STREQUAL "mips")
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS MIPS_FPU_LE=1)
+endif()
+
+if(simd_inst STREQUAL "neon")
+  list(APPEND WEBRTC_COMPILE_DEFINITIONS WEBRTC_HAS_NEON=1)
+endif()

cmake/FindBCG729.cmake

@@ -0,0 +1,48 @@
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+  pkg_search_module(PC_BCG729 bcg729 libbcg729)
+  set(BCG729_VERSION ${PC_BCG729_VERSION})
+endif()
+
+find_path(BCG729_INCLUDE_DIR
+  NAMES
+    "bcg729/encoder.h"
+  HINTS
+    ${PC_BCG729_INCLUDEDIR}
+    ${PC_BCG729_INCLUDE_DIRS}
+)
+mark_as_advanced(BCG729_INCLUDE_DIR)
+
+find_library(BCG729_LIBRARY
+  NAMES
+    bcg729
+    libbcg729
+  HINTS
+    ${PC_BCG729_LIBDIR}
+    ${PC_BCG729_LIBRARY_DIRS}
+)
+mark_as_advanced(BCG729_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(BCG729
+  REQUIRED_VARS
+    BCG729_LIBRARY
+    BCG729_INCLUDE_DIR
+  VERSION_VAR
+    BCG729_VERSION
+)
+
+if(BCG729_FOUND)
+  set(BCG729_LIBRARIES ${BCG729_LIBRARY})
+  set(BCG729_INCLUDE_DIRS ${BCG729_INCLUDE_DIR})
+  set(BCG729_DEFINITIONS ${PC_BCG729_CFLAGS_OTHER})
+
+  if(NOT TARGET BCG729::BCG729)
+    add_library(BCG729::BCG729 UNKNOWN IMPORTED)
+    set_target_properties(BCG729::BCG729 PROPERTIES
+      IMPORTED_LOCATION "${BCG729_LIBRARIES}"
+      INTERFACE_INCLUDE_DIRECTORIES "${BCG729_INCLUDE_DIRS}"
+      INTERFACE_COMPILE_OPTIONS "${BCG729_DEFINITIONS}"
+    )
+  endif()
+endif()

cmake/FindCoreAudio.cmake

@@ -0,0 +1,34 @@
+set(_coreaudio_libs)
+foreach(_coreaudio_lib IN ITEMS CoreAudio AudioToolbox Foundation AppKit)
+  string(TOUPPER "CoreAudio_LIBRARY_${_coreaudio_lib}" _coreaudio_lib_var)
+  list(APPEND _coreaudio_required_vars ${_coreaudio_lib_var})
+
+  find_library(${_coreaudio_lib_var} "${_coreaudio_lib}")
+  mark_as_advanced(${_coreaudio_lib_var})
+  if(${_coreaudio_lib_var})
+    list(APPEND _coreaudio_libs "${${_coreaudio_lib_var}}")
+  endif()
+endforeach()
+unset(_coreaudio_lib)
+unset(_coreaudio_lib_var)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(CoreAudio
+  REQUIRED_VARS
+    ${_coreaudio_required_vars}
+)
+
+if(CoreAudio_FOUND)
+  set(CoreAudio_LIBRARIES ${_coreaudio_libs})
+
+  if(NOT TARGET CoreAudio::CoreAudio)
+    add_library(coreaudio INTERFACE)
+    set_target_properties(coreaudio PROPERTIES
+      INTERFACE_LINK_LIBRARIES "${CoreAudio_LIBRARIES}"
+    )
+    add_library(CoreAudio::CoreAudio ALIAS coreaudio)
+  endif()
+endif()
+
+unset(_coreaudio_libs)
+unset(_coreaudio_required_vars)